Classement de valeurs

Bonjour je vous sollicite à nouveau votre aide car je suis bloqué sur un dossier . Je souhaiterais faire un classement a partir d'un tableau à deux colonnes . Les 3 plus grosses valeurs situées en colonne 2 pour chaque valeur se situant en colonne 1.J'ai mis un fichier en exemple . Merci

Bonjour,

en G4 et à tirer vers le bas

=SOMMEPROD(GRANDE.VALEUR(($A$4:$A$16=$F4)*($B$4:$B$16);NB.SI($F$4:$F4;$F4)))

Cdlt

Bonjour merci de ton aide elle fonctionne ta formule mais j'ai des fichiers avec des données importantes donc la formule n'est pas la solution si je dois tirer la formule à chaque fois mais encore merci.

Bonjour,

Pour reproduire une formule sur une grande quantité de lignes, il suffit de se positionner sur le coin en bas à droite (la croix du curseur devient plus fine) de la première cellule qui contient la formule et de faire un double-clic.

Explication en vidéo

Cdlt

Bonjour je connaissais cette astuce mais mon tableau est le résultat d'un code vba et j'aurais souhaité que la deuxième partie soit aussi en vba pour éviter toute intervention manuelle...Mais merci de ces explications.

Bonjour,

Voilà en VBA

Sub ApplicationFormule()
    Dim DerLig_Liste As Long, DerLig_Extract As Long, i As Long, j As Long
    Application.ScreenUpdating = False
    DerLig_Liste = Range("A" & Rows.Count).End(xlUp).Row

    'Constitution de la liste des véhicule
    Range("A3:A16").AdvancedFilter Action:=xlFilterCopy, CopyToRange:=Range("F3"), Unique:=True

    'Triplement de chaque véhicule
    DerLig_Extract = Range("F" & Rows.Count).End(xlUp).Row
    For i = DerLig_Extract To 4 Step -1
        For j = 1 To 2
            Cells(i, "F").Copy
            Cells(i, "F").Insert Shift:=xlDown
        Next j
    Next i

    'tri de la colonne F par ordre alphabétique
    DerLig_Extract = Range("F" & Rows.Count).End(xlUp).Row
    Range("F4:F" & DerLig_Extract).Sort [F3], 1

    'Application de la formule
    Range("G4").FormulaR1C1 = "=SUMPRODUCT(LARGE((R4C1:R" & DerLig_Liste & "C1=RC6)*(R4C2:R" & DerLig_Liste & "C2),COUNTIF(R4C6:RC6,RC6)))"
    Range("G4").AutoFill Destination:=Range("G4:G" & DerLig_Extract)

    'Remplacement de la formule par les valeurs obtenues
    Range("G4:G" & DerLig_Extract).Value = Range("G4:G" & DerLig_Extract).Value

    'Suppression des véhicules avec la valeur = à 0
    For i = DerLig_Extract To 4 Step -1
        If Cells(i, "G") = 0 Then Range(Cells(i, "F"), Cells(i, "G")).Delete
    Next i
End Sub

Cdlt

Bonjour

Merci Arturo83 ton code fonctionne je peux l'intégrer dans mon projet.Super.