Extraction de nombre dans du texte

Bonjour à tous,

Je suis confronté à un problème : je voudrais extraire des nombres dans du texte.

Je m'explique :

J'ai dans une cellule : xxxxtexte - 21548 xxxxxxtexte et je voudrais extraire seulement le nombre correspondant dans une autre cellule.

Sachant aussi que ce nombre peut varier, il peut être plus ou moins grand. En fait ce sont des articles comptable...

Si vous y arriver, j'aimerais aussi rajouter un point (.) à la fin de ce nombre... Cela m'aiderait à faire des recherches SOMME.SI.ENS directement depuis les situations comptable de mon logiciel.

Je vous en remercie d'avance !

Bonjour,

Si vos données sont présentées avec un nombre d'espaces bien fixes c'est à dire, votre texte, un espace, un tiret, un espace votre série de chiffre et un espaces alors en B1 pour un texte en A1 :

=STXT(SUBSTITUE(SUBSTITUE(A1;" ";"";2);" ";"";1);CHERCHE(" ";SUBSTITUE(A1;" ";"";1));CHERCHE(" ";SUBSTITUE(SUBSTITUE(A1;" ";"";2);" ";"";1))-CHERCHE(" ";SUBSTITUE(A1;" ";"";1)))&"."

Sinon merci de fournir un panel représentatif de toutes vos cas possibles.

Cdlt,

J'ai rien compris à la formule magique mais ça fonctionne extrêmement bien !

Une solution dans le cas ou il n'y a pas d’espace avec le texte directement après le nombre ? (ex : Art. - 6811(ordre)).

Si non je m'arrange pour mettre un espace

Merci beaucoup !

Bonjour à toutes et tous, JB, Ergotamine,

@JB

A tester cette formule

=RECHERCHE(9^9;--("0"&STXT(A1;MIN(CHERCHE({0.1.2.3.4.5.6.7.8.9};A1&"0123456789"));LIGNE($1:$100))))&"."

Cordialement.

Bonjour,

C'est possible oui, mais en soit je vous conseille fortement que le formalisme des données soit standardisé. Tout dépend du nombre de données à traiter manuellement, de leur typologies, etc ... On peut envisager un prétraitement par VBA en remplaçant les caractères qui nous embêtent (exemple remplacer les parenthèses par des espaces), etc ... Mais il faut réaliser ce travail d'analyse en amont pour être sûr de couvrir tous les cas. Libre à vous en fonction de votre ressenti et la nécessité de réaliser ce travail ou non.

Pour les explications de la formule :

=SUBSTITUE(SUBSTITUE(A1;" ";"";2);" ";"";1) 'Remplace les espaces par rien, donc xxxxtexte-21548 xxxxxxtexte
=CHERCHE(" ";SUBSTITUE(A1;" ";"";1)) 'Renvoie la position du premier espace rencontré dans la chaîne xxxxtexte- 21548 xxxxxxtexte où j'ai supprimé le premier espace via SUBSTITUE donc la position du 1er chiffre. Soit ici 11.
=CHERCHE(" ";SUBSTITUE(SUBSTITUE(A1;" ";"";2);" ";"";1))-CHERCHE(" ";SUBSTITUE(A1;" ";"";1)) 'Renvoie le nombre de caractère entre le premier espace et le second en ayant supprimé le 1er espace avant le -. Donc le nombre de caractère compris dans la chaîne numérique soit ici 5
=STXT(SUBSTITUE(SUBSTITUE(A1;" ";"";2);" ";"";1);CHERCHE(" ";SUBSTITUE(A1;" ";"";1));CHERCHE(" ";SUBSTITUE(SUBSTITUE(A1;" ";"";2);" ";"";1))-CHERCHE(" ";SUBSTITUE(A1;" ";"";1)))&"." 'Extrait depuis la chaîne de caractère sans espaces, à partir de la position 11, sur une longueur de 5 caractères et ajoute un "." à la fin via &

Cdlt,

Edit : Bonjour mdo100, longtemps que je ne t'avais pas croisé ! Je pense que ta formule est plus efficace que la mienne ! Bravo !

Merci pour les explications !

Effectivement, la formule de mdo100 fonctionne très bien aussi. Cependant, les 0 avant le nombre ne s'affichent pas comme dans la formule de Ergotamine. Une solution peut-être ?

Re JB,

Si tu n'es pas allergique au VBA, voici une fonction personnalisée qui se comporte comme une fonction native d'Excel.

La fonction est à mettre dans un module et il faut enregistrer le fichier en .xlsm

Cdlt.

@Ergotamine,

Oui pas souvent ici sur le forum, mes soucis de santé ne s'arrange pas.

Cdlt.

Ça fonctionne parfaitement ! merci à vous.

J'ai encore du travail pour arriver à votre niveau

RE,

Est-ce que quelqu'un saurait comment ajouter un point (.) derrière une liste de nombre ?

Par exemple, ma colonne A comporte 1000 lignes avec des nombres et je voudrais ajouter ce point derrière chaque nombre ?

Je bloque, merci d'avance !

Bonjour JB,

Commence par passer ce sujet en résolu sous la ou les solutions qui ton aidées a résoudre ton problème.

Et ouvre un nouveau post concernant ta dernière demande.

Cdlt.