Rechercher un mail et y répondre

Le 18/05/2021 à 08:58
Bonjour à tous,

J'ai plusieurs ligne de données dans un Excel. A chaque fois que je rempli une ligne, un mail part à la personne concernée.
Cependant, je souhaite que lorsque je rajoute une donnée supplémentaire à la ligne après avoir envoyer mon mail, que cela recherche automatiquement mon mail concernée et rajoute dans le corps du mail la donnée que j'ai rajoutée.

Mon plus gros problème est de ne pas réussir à sélectionner le mail. J'arrive à le trouver par exemple en le recherchant dans la barre de recherche de Outlook mais pas à le sélectionner.
Il sélectionne toujours le dernier mail actif.

J'ai cherché une solution sur ce forum et d'autre mais jamais de solutions qui soit claire ou fonctionnelle.

Je m'en remets donc à vos compétences. Merci d'avance.

Voici un début de piste que j'ai eu.

Sub Répondre()

Dim olSpace, o As Object
Dim ns As Namespace
Dim Inbox As MAPIFolder
Dim Item As Object
Dim Sujet As String
Dim myOlExp As outlook.Explorer
Dim myOlSel As outlook.Selection
Dim oMail As outlook.MailItem

Set o = CreateObject("Outlook.Application")
Set olSpace = o.GetNamespace("MAPI")
Set olInbox = olSpace.GetDefaultFolder(6)

Sujet = "TR: 20075 +20076 commandes 211340 + 211341"

Set myOlExp = outlook.ActiveExplorer
Set myOlSel = myOlExp.Selection
Set oMail = myOlSel.Item(1)
oMail.Reply
oMail.Display

End Sub
Le 18/05/2021 à 11:17

Bonjour,

Essayer ce code

Sub Répondre()

    Dim olApp As Outlook.Application
    Dim emails_envoyés As Outlook.Folder
    Dim emails_trouvés As Outlook.Items
    Dim email As Outlook.MailItem
    Dim sujet As String, filtre As String

    'définition application
    Set olApp = Outlook.Application

    'affectation mails envoyés
    Set emails_envoyés = olApp.Session.GetDefaultFolder(olFolderSentMail)

    'recherche des emails envoyés correspondant au sujet
    sujet = "TR: 20075 +20076 commandes 211340 + 211341"
    filtre = "@SQL=" & Chr(34) & "urn:schemas:httpmail:subject" & Chr(34) & " like '%" & sujet & "%'"
    Set emails_trouvés = emails_envoyés.Items.Restrict(filtre)

    'exploitation des emails trouvés
    For Each email In emails_trouvés
        email.Display
    Next email

End Sub
Le 18/05/2021 à 11:57

Bonjour, cela ne marche pas, je pense que cela vient de la variable filtre

Le 18/05/2021 à 12:24

je pense que cela vient de la variable filtre
Certainement pas car je l'ai testée avec mes messages envoyés. Votre problème est ailleurs. C'est que vos messages ne sont pas dans les éléments envoyés.

Le 20/05/2021 à 17:18

Re,

dsl pour le temps que je met à répondre;

thev, effectivement, le filtre marche, le sujet qui était donné dans mon exemple ne marchait pas (aucune idée de pourquoi).

Cependant, quand je fais fonctionner la macro, le mail s'affiche mais je ne peux pas écrire dedans car il est considéré comme un .Items et non .MailItem

je ne peux donc pas par exemple programmé du texte qui s'insère automatique dedans.

Le 20/05/2021 à 17:34

Bonjour,

ci-joint code pour réponse

Sub Répondre()

    Dim olApp As Outlook.Application
    Dim emails_envoyés As Outlook.Folder
    Dim emails_trouvés As Outlook.Items
    Dim email As Outlook.MailItem, email_réponse As Outlook.MailItem
    Dim sujet As String, filtre As String

    'définition application
    Set olApp = Outlook.Application

    'affectation mails envoyés
    Set emails_envoyés = olApp.Session.GetDefaultFolder(olFolderSentMail)

    'recherche des emails envoyés correspondant au sujet
    sujet = "TR: 20075 +20076 commandes 211340 + 211341"
    filtre = "@SQL=" & Chr(34) & "urn:schemas:httpmail:subject" & Chr(34) & " like '%" & sujet & "%'"
    Set emails_trouvés = emails_envoyés.Items.Restrict(filtre)

    'exploitation des emails trouvés
    For Each email In emails_trouvés
        Set email_réponse = email.Reply
        email_réponse.Display
    Next email

End Sub
Rechercher des sujets similaires à "rechercher mail repondre"