Copier des colonnes séparées

Bonjour,

J'essaye de copier des colonnes qui sont séparées dans excel vers word, exemple j'essaye de copier les colonnes C et D ainsi que la colonne G pour les regrouper dans un même tableau, le problème c'est qu'avec ma macro, lorsque je les sélectionne ça me copie aussi les colonnes E et F qui contiennent des données dont je n'ai pas besoin dans ma copie.

Ma commande actuelle est la suivante :

Range("C5:D13,G5:G13").Select
Selection.Copy

Je ne sélectionne pas les colonnes E et F et pourtant ça me les copie quand même, quelqu'un peut-il m'éclairer ?

Merci

Je viens aussi d'essayer en faisant :

Set plage1 = Sheets("Vulne_Conf").Range("C5:D" & LastRow)
Set plage2 = Sheets("Vulne_Conf").Range("G5:G" & LastRow)
Set plage3 = Union(plage1, plage2)

plage3.Select
Selection.Copy

J'obtiens les mêmes résultats

Bonjour,

Un test :

With Worksheets("Vulne_Conf")
    Application.Union(.Range("C5:D" & LastRow), .Range("G5:G" & LastRow)).Select
End With

Normalement vous devriez avoir vos 2 plages sélectionnées. Sinon qu'avez vous de selectionné ? Vous pouvez remplacer Select par copy pour copier directement les zones.

Sinon merci de joindre un fichier représentatif à la demande.

Cdlt,

PS : Je ne m'intéresse pas au collage inter applicatif pour le moment.

Ok, tout d'abord merci pour votre réponse, en premier lieu j'ai testé et ça ne fonctionnait pas, en tout cas lorsque je copie directement vers word, en revanche lorsque je copie vers une autre cellule d'excel :

Sub test()

Dim LastRow As Long
LastRow = Cells(Rows.Count, 4).End(xlUp).Row

With Worksheets("Feuil1")
Application.Union(.Range("C5:D" & LastRow), .Range("G5:G" & LastRow)).Select
Selection.Copy Destination:=Range("j5")
End With

End Sub

Cela fonctionne très bien, je n'ai pas les colonnes E et F qui ne m'intéressent pas, une idée de pourquoi j'ai quand même les colonnes lorsque je copie vers word ?

Pour copier vers le word j'utilise :

Set Plg = WordApp.Selection.Range

WordApp.Selection.PasteExcelTable True, False, False

Bonjour,

Je me souviens désormais comment j'avais fait. En fait j'avais masqué les colonnes dont je n'avais pas besoin avant de copier la zone et la coller. Un exemple :

Sub test()
Dim LR As Long
Dim APP As Object, DOC As Object
LR = Cells(Rows.Count, 4).End(xlUp).Row
With Worksheets("Feuil1")
    .Columns("E:F").Hidden = True
    .Range("C5:G" & LR).Copy
End With
If APP Is Nothing Then Set APP = CreateObject("Word.Application")
Set DOC = APP.Documents.Add
DOC.Activate
APP.Selection.PasteExcelTable False, False, True
APP.Visible = True
Worksheets("Feuil1").Columns("E:F").Hidden = False
End Sub

C'est peut être pas propre, mais fonctionnel chez moi !

Cdlt,

Ahhh pas bête du tout, merci de l'astuce :)

Je viens de tester ça marche au top :D merci !

Bonjour,

Merci du retour. Une autre solution aurait été de copier coller la plage "fusionnée" sur une feuille intermédiaire, puis de recopier cette plage vers le document word et enfin de nettoyer la plage "fusionnée" intermédiaire.

N'hésitez pas à passer votre sujet en résolu si c'est le cas afin d'améliorer la lisibilité du forum.

Cdlt,