Changement de thème export pdf

Bonjour à tous,

Je rencontre actuellement un problème sur un export pdf d'une feuille de mon classeur vers un dossier de mon ordinateur. J'ai codé une macro pour réaliser cet export et affecter cette macro à un bouton. Cependant l'export qui est réalisé prend un autre thème que celui de mon classeur initial. Ma macro est la suivante :

Option Explicit

Sub Bouton3()

'Feuille "Pilotage", bouton "Export recette"

Dim Répertoire As String, _
    Fichier As String, _
    Datedujour As String, _
    Brassin As Variant, _
    DerLigneVide As Variant

    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With

    'Si la feuille est vide on stoppe tout.
    If IsEmpty(ActiveSheet.UsedRange) Then Exit Sub

    'on récupère la date et nom de brassin

    Datedujour = Format(Date, "dd" & "." & "mm" & "." & "yyyy")
    Brassin = Range("J20").Value

    'Dossier de destination des fichiers PDF créés
    Répertoire = "C:\Users\TISON Clément\Desktop\Brew\Brassins\"

    'On crée un nouveau document en copiant la feuille active
    ActiveSheet.Copy

    With ActiveSheet
        'On donne au fichier PDF le nom "Date-Brassin"
        Fichier = Datedujour & "-" & Brassin & ".pdf"
        'On crée le nouveau document au format PDF
        .ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=Répertoire & Fichier, _
            Quality:=xlQualityMinimum, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=False
    End With

    'On ferme le document que l'on vient de créer
    ActiveWorkbook.Close False

MsgBox ("Brassin exporté")

End Sub

Avez vous une idée pour solutionner ce problème ?

ps : un code similaire fonctionne parfaitement pour exporter une autre feuille de ce même classeur !

Merci d'avance

Clément

Bonjour Clément,

ajoute cette ligne

ActiveWorkbook.ApplyTheme (ThisWorkbook.Path & "\" & ThisWorkbook.Name)

après la ligne

ActiveSheet.Copy

P.S.
Je ne comprends pas la nécessité de copier la feuille active avant de créer le pdf, ça devrait suffire:

Sub Bouton3Seq()

'Feuille "Pilotage", bouton "Export recette"

Dim Répertoire As String, Fichier As String, Datedujour As String, Brassin As String

    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With

     'Si la feuille est vide on stoppe tout.
    If IsEmpty(ActiveSheet.UsedRange) Then Exit Sub

    'on récupère la date et nom de brassin

    Datedujour = Format(Date, "dd" & "." & "mm" & "." & "yyyy")
    Brassin = Range("J20").Value

    'Dossier de destination des fichiers PDF créés
    Répertoire = "C:\Users\TISON Clément\Desktop\Brew\Brassins\"

       With ActiveSheet
        'On donne au fichier PDF le nom "Date-Brassin"
        Fichier = Datedujour & "-" & Brassin & ".pdf"
        'On crée le nouveau document au format PDF
        .ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=Répertoire & Fichier, _
            Quality:=xlQualityMinimum, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=False
    End With

   MsgBox ("Brassin exporté")

End Sub

Cordialement,