Parcourir une feuille pour trouver valeur identique dans l'autre

Bonjour, j'ai un document Excel avec 2 feuilles, la première contient des numéros (exemple de 1 à 10) dans la colonne A et la deuxième feuille contient ces mêmes numéros une ou plusieurs fois dans la colonne A avec des salaires associés dans la colonne B. En gros, les numéros sont des numéros d'employés auquel on verse un salaire plusieurs fois par année. Le but est que pour chaque numéro de la feuille 1 je veux parcourir les salaires de la feuilles 2 et faire la somme de tous les salaires associés à l'employé (numéro).

Voici le code que j'ai commencé à faire :

Sub salaires()
Dim feuil1 As Worksheet, feuil2 As Worksheet
Dim i As Long, derniere As Long
Dim zone As Range

Set feuil1 = Worksheets("numero")
Set feuil2 = Worksheets("salaire")
derniere = feuil1.Cells(Rows.Count, "A").End(xlUp).Row

'Parcourir la colonne 1 feuille 1
For i = 2 To derniere 'définir quel est la ligne de départ
'recherche produit dans la colonne A de la feuille 2
Set zone = feuil2.Columns("A").Find(feuil1.Cells(i, "A").Value, LookIn:=xlValues, lookat:=xlWhole)

Next

End Sub

Je ne sais pas quoi faire ensuite pour pouvoir calculer la somme des salaires de la colonne B de la feuille 2 pour chacun des numéros. Quelqu'un aurait une idée?

bonsoir

sans vba ; un simple SOMME.SI doit y suffire

cordialement

Merci bonne soirée

Bonjour tout le monde. Avec VBA tu n'étais pas loin. C'est dommage de ne pas être allé au bout.

Sub salaires()
    Dim feuil1 As Worksheet, feuil2 As Worksheet
    Dim i As Long, j As Long
    Dim derniere1 As Long, derniere2 As Long
    Dim zone As Range
    Dim total As Double

    Set feuil1 = Worksheets("numero")
    derniere1 = feuil1.Cells(Rows.Count, "A").End(xlUp).Row
    Set feuil2 = Worksheets("salaire")
    derniere2 = feuil2.Cells(Rows.Count, "A").End(xlUp).Row

    'Parcourir la colonne 1 feuille 1
    For i = 2 To derniere1 'définir quel est la ligne de départ
        total = 0
        ' Parcourir la colonne 1 feuille 2
        For j = 1 To derniere2
            If feuil2.Cells(j, 1) = feuil1.Cells(i, 1) Then
                total = total + feuil2.Cells(j, 2)
            End If
        Next j
        feuil1.Cells(i, 3) = total
    Next

End Sub