Supression des doublons

Bonjour

je cherche a supprimer les lignes sur un tableau avec comme condition les valeurs en double dans la colonne C (Operation) mais sans supprimer les lignes avec la valeur #N/A

merci d'avance

Bonjour GUELLILA, le forum,

Donc :

si dans la colonne C, la valeur est présente plus d'une fois mais différente de #N/A,

on supprime toute la ligne sans se soucier des colonnes A et B

A tester:

CTRL + e pour exécuter la macro.

Cordialement,

Bonsoir …

Dans l’onglet Feuil1,une plage (cellules contiguës) nommée BD, pour supprimer les doublons de sa colonne 2, tester

Sub u()
    Feuil1.[BD].Columns(2).RemoveDuplicates 1
End Sub

Bonsoir xorsankukai

je viens de tester ta macro malheureusement elle supprime toutes les lignes et ne reponds pas a mes besoins

merci encore une fois

Bonjour,

Une proposition Power Query.

Cdlt.

Bonjour tout le monde,

xorsankukai

je viens de tester ta macro malheureusement elle supprime toutes les lignes et ne reponds pas a mes besoins

La macro ne tient compte que des doublons en colonne C (exceptés les #N/A).

Ceci dit, lorsque je vois la solution de Jean-Eric (), je constate que je n'avais pas compris tes besoins,

Je te laisse donc avec l'expert,

@Jean-Eric : juste par curiosité, est-ce réalisable par macro ?

Bon dimanche,

Cordialement,

Bonjour

merci a vous tous pour votre aide

xorsankukai : pour répondre a ta question ci-dessous le code VBA

merci encore une fois

Option Explicit

Sub Supprimer_doublons()
Dim d As Object, a, i&, x
Set d = CreateObject("Scripting.Dictionary")
Application.ScreenUpdating = False
If ActiveSheet.FilterMode Then ActiveSheet.ShowAllData 'si la feuille est filtrée
With [A1].CurrentRegion.EntireRow 'lignes entières pour conserver les hauteurs des lignes
    a = .Columns(3).Resize(, 2) 'matrice, plus rapide, au moins 2 éléments
    For i = 1 To UBound(a)
        x = a(i, 1)
        If IsError(x) Then
            a(i, 1) = 1
        Else
            If d.exists(x) Then a(i, 1) = "#N/A" Else a(i, 1) = 1: d(x) = ""
        End If
    Next
    '---restitution et filtrage---
    .Columns(3).EntireColumn.Insert 'insère une colonne auxiliaire
    .Columns(3) = a
    .Sort .Columns(3), xlAscending 'tri pour regrouper et accélérer
    On Error Resume Next 'si aucune SpecialCell
    .Columns(3).SpecialCells(xlCellTypeConstants, 16).EntireRow.Delete 'supprime les doublons
    .Columns(3).EntireColumn.Delete 'supprime la colonne auxiliaire
End With
End Sub

a+

Bonjour à tous,

Voici une proposition tout en mémoire :

Sub dedoublonner()
set dico = createobject("Scripting.Dictionary")
with activesheet.cells(1, 1).currentregion
    t = .value
    for i = lbound(t) to ubound(t)
        if not dico.exists(t(i, 3)) or iserror(t(i, 3)) then 'merci Xorsankukai :)
            n = n + 1
            dico(t(i, 3)) = ""
            for k = lbound(t, 2) to ubound(t, 2)
                t(n, k) = t(i, k)
            next k
        end if
    next i
    .clearcontents
    if n > 0 then .resize(n, ubound(t, 2)).value = t
end with
end sub

Cdlt,

Re,

Merci GUELLILA et 3GB pour la solution via macro, , ça satisfait pleinement ma curiosité,

@3GB: lorsque je teste ton code , j'ai une erreur ici:

que j'arrive à palier avec

En tout cas, joli code,

Bon dimanche à tous,

Cordialement,

Salut Xorsankukai !

Oui, j'avais un petit doute à ce niveau. Je pense qu'en chargeant le tableau t avec la propriété .value2, ça pourrait passer (je n'ai pas essayé). Par contre, il est possible que ça perturbe la reconnaissance des doublons puisqu'il s'agit de décimaux...

En tout cas, merci pour la confirmation !

A plus,