Verrouiller la liste des champs TCD

Bonjour, dans un TCD y a t-ti une solution pour verrouiller l'accès au tableau de la liste des champs pour ne pas permettre à une autre personne de déplacer ou supprimer les champs ? mERCI

Bonjour,

As-tu essayé de protéger la feuille ?

Sinon, souhaites-tu une solution VBA ?

Cdlt.

protéger la feuille je l'utilise pour la feuille de BD mais dans le TCD on peut accéder à la liste des champs. Oui s'il n'y a pas d'autre solution que le VBA oui je suis d'accord merci.

Bonjour,

Une proposition à adapter.

Cdlt.

Private Sub ProtectionPivotTable(bln As Boolean)
'Au lieu de . PivotFields, vous pouvez utiliser . RowFields, . ColumnFields ou . Pagefields
Dim pf As PivotField
    On Error Resume Next
    With ActiveSheet.PivotTables(1)
        .EnableDrilldown = bln
        .EnableFieldList = bln
        .EnableFieldDialog = bln
        '.PivotCache.EnableRefresh = bln
        For Each pf In .PivotFields
            With pf
                .DragToPage = bln
                .DragToRow = bln
                .DragToColumn = bln
                .DragToData = bln
                .DragToHide = bln
            End With
        Next pf
    End With
End Sub

Public Sub RestrictPivottable()
    ProtectionPivotTable False
End Sub

Public Sub AllowPivottable()
    ProtectionPivotTable True
End Sub

Merci beaucoup !