Export PDF vers une destination demandée

Bonjour,

J'ai essayé de faire un export pdf qui fonctionne correctement à 2/3 détails prêt. J'ai bien défini ma zone d'impression cependant je n'ai pas tout sur l'export. De plus j'aimerai que l'export soit enregistré la ou la personne le souhaite (avec une fenêtre de demande).Et pour finir le nom de on fichier générer ne fonctionne plus depuis que j'ai rajouter une cellule dans le titre("L'indice n'appartient pas à la sélection").

Ci-joint le code actuel:

Sub PDF_SAVE()

Dim LHeure As String, LeDate As String

LHeure = Format(Time, "HH" & "MM")

LaDate = Format(Date, "dd" & "." & "mm" & "." & "yyyy")

' Création fichier PDF

ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _

"C:\Chiffrage_Systèmes Connectés IDF_ " & Sheets(" Onglet_mémoire ").Range(" A2 ") & LaDate & " " & LHeure & " .pdf ", Quality:= _

xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _

From:=1, To:=1, OpenAfterPublish:=False

' Message de confirmation

MsgBox ("Création du fichier PDF effectué" & vbCrLf & vbCrLf & "Merci ")

End Sub

Merci pour ceux qui prendront le temps de me lire

Bonjour,

Alors, l'édition est partielle car vous prenez seulement la première page (from 1 to 1). J'ai enlevé ces paramètres mais le mieux serait de bricoler vos sauts de pages pour obtenir le rendu désiré...

J'ai changé le format de la date en privilégiant AAAAMMJJ pour un tri chronologique automatique et ai remplacé les points par des tirets (préférables sur des noms de fichiers).

Voici un essai :

Sub PDF_SAVE()

Dim fd as FileDialog
Dim sdate$, dossier$, nomfichier$

sdate = Format(Now, "yyyy-mm-dd hh-mm")
nomfichier = Sheets("Onglet_mémoire").Range("A2").value & " " & sdate & ".pdf" '<<<< A VOIR (onglet memoire et A2, éviter accents et espaces)
Set fd = Application.FileDialog(msoFileDialogFolderPicker) 'boite de dialogue séléection répertoire

With fd 'avec boite de dialogue
    .Title = "Sélectionner le répertoire de l'enregistrement :" 'titre
    .Show 'affiche
    if not .SelectedItems.Count = 1 then 'si sélection <> 1
        msgbox "Veuillez sélectionner un dossier !", vbcritical, "Erreur - sélection de dossier" 'msg
        Exit Sub 'sortie
    else 'sinon
        dossier = .SelectedItems(1) 'dossier = répertoire sélectionné
    end if
End With

With sheets("nomfeuilleaexporter") '<<< ADAPTER
    .ExportAsFixedFormat Type:=xlTypePDF, Filename:=dossier & "\" & nomfichier, IgnorePrintAreas:=False
End with

MsgBox "Création du fichier PDF effectuée" & vbCrLf & vbCrLf & "Merci"

End Sub

Il faut examiner vos noms de feuilles dans le code et sur votre fichier. L'erreur provient probablement de là.

Cdlt,

Cela fonctionne merci beaucoup!

Super !