Réduire et afficher ruban

Bonjour à tous ,

Dans mon fichier excel je souhaites que le ruban se réduise lorsque mon classeur est ouvert et s'affiche à nouveau si je quitte le classeur ou le réduit (pour travailler sur d'autres classeurs par exemple). Est-ce faisable ?
Je précise que je souhaites bien réduire et non le masquer complètement ;-).

Voilà ce que j'ai mis déjà comme code pour le réduire à l'ouverture et qui marche très bien :

Private Sub Workbook_Activate()
    With Application
    If .CommandBars("Ribbon").Height > 100 Then SendKeys "^{F1}"
    End With
End Sub

Il me manque maintenant la même chose mais pour le faire réapparaître lors de la fermeture ou lorsque j'ouvre un autre classeur en réduisant celui-ci.

Salutations,
Cédric Pillonel.

Bonjour,

Dans quel but réduire le ruban?

Qu'elle est la finalité de tout ceci?

Bonjour,

Ce code a l'air de fonctionner. Doit y avoir plus optimisé, mais j'ai pas trouvé mieux.

Private Sub Workbook_Activate()
    With Application
    If .CommandBars("Ribbon").Height > 100 Then SendKeys "^{F1}"
    End With
End Sub

Private Sub Workbook_Deactivate()
    With Application
    If .CommandBars("Ribbon").Height < 100 Then SendKeys "^{F1}"
    End With
End Sub

edit : J'avais pas vu que tu étais intervenu Pijaku, j'ai mis 3 plombes à pondre ces 4 lignes ^^

Afin d'afficher uniquement l'essentiel sur la page et d'avoir la visibilité sur le plus d'espace du document sans avoir le ruban qui doit cacher 10% environ. Et pas le masquer complétement car je souhaites donner la possibilité d'utiliser le ruban aux utilisateurs s'ils en ont besoin.

En fait, le souci ici, est que en fonction des enregistrements, des "voyages" entre classeurs, tu vas te retrouver avec des classeurs autres que celui-ci qui auront le ruban masqué, le tien qui ne sera pas toujours masqué, etc...

Difficile de gérer un objet du niveau "Application" au niveau inférieur "Workbook"...

Il serait peut-être plus "agile", mais plus complexe, de le gérer au niveau Application...

J'ai bien dit "peut-être".

Si tu veux essayer, je veux bien tenter de m'y mettre...

En plus j'ai l'impression que mon code désactive le pavé numérique?

Bon.
Mes premiers essais semblent concluants.

Ce code est à placer dans le module ThisWorkbook, adapter la constante WBKNAME :

Option Explicit

Private WithEvents App As Application
Private Const WBKNAME As String = "Classeur1.xlsm"  ' A ADAPTER : le nom du classeur concerné

Private Sub Workbook_Open()
    Set App = Application
End Sub

Private Sub App_WorkbookActivate(ByVal Wb As Workbook)
On Error Resume Next
    If Wb.Name = WBKNAME Then
        With App
            If .CommandBars("Ribbon").Height > 100 Then .CommandBars.ExecuteMso "MinimizeRibbon"
        End With
    End If
End Sub

Private Sub App_WorkbookOpen(ByVal Wb As Workbook)
On Error Resume Next
    If Wb.Name = WBKNAME Then
        With App
            If .CommandBars("Ribbon").Height > 100 Then .CommandBars.ExecuteMso "MinimizeRibbon"
        End With
    End If
End Sub

Private Sub App_WorkbookBeforeClose(ByVal Wb As Workbook, Cancel As Boolean)
On Error Resume Next
    If Wb.Name = WBKNAME Then
        With App
            If .CommandBars("Ribbon").Height < 100 Then .CommandBars.ExecuteMso "MinimizeRibbon"
        End With
    End If
End Sub

Private Sub App_WorkbookDeactivate(ByVal Wb As Workbook)
On Error Resume Next
    If Wb.Name = WBKNAME Then
        With App
            If .CommandBars("Ribbon").Height < 100 Then .CommandBars.ExecuteMso "MinimizeRibbon"
        End With
    End If
End Sub

Bonjour,

On peut peut-être rappeler les options d'affichage du ruban ?

Bonsoir à tous ,

Désolé pour le délai de réponse ...
Je vous remercie à tous d'avoir participé à mon problème ! J'ai choisi l'option de JoyeuxNoel malgré la proposition de pijaku qui me semble meilleur mais le fichier peu changer de nom et mes collègues ne sauront pas comment modifier le VBA en conséquence .

Pour ce qui est du pavé numérique qui se désactive après le code de JoyeuxNoel, j'ai rajouté SendKeys ("{NUMLOCK}") après la commande pour pouvoir avoir à nouveau le pavé numérique qui s'active .

Merci à tous !

Salutations,
Cédric Pillonel.