Macro Count Team

Bonsoir à tous les membres du forum,

J'espère que vous allez bien.

Je viens à vous car j'aimerais réaliser la macro suivante à partir du fichier ci-dessous.

Le but est de la macro est de partir de la feuille "Tableau MAX", de créer 2 colonnes supplémentaires en C et inscrire en B2 : "NOMBRES APPARITIONS".

Ensuite, pour chaque ligne :

- Utiliser en colonne B, à partir de la ligne 3 jusqu'à la dernière ligne qui a du contenu dans la colonne C, la fonction NB.SI en prenant comme plage la cellule D3 jusqu'à la dernière ligne qui contient du contenu dans la colonne D dans la feuille Aggregate. Et prendre comme critère le nom de l'équipe en colonne C de la feuille "Tableau Max"

- Ajouter des couleurs 3 mises en forme conditionnelles :

1- Si < 150, attribuer à la cellule un fond rouge et une police blanche

2- Si la valeur est comprise entre 150 et 250, attribuer à la cellule un fond orange et une police blanche

3- Si la valeur est comprise entre > 250, attribuer à la cellule un fond vert et une police blanche

(Peut-être attribuer des couleurs plus claires et pas autant foncés car c'est vrai que ça pique aux yeux )

PS : Il est normal qu'il n'y ait pas de cellules vertes car j'ai volontairement retirer des lignes dans la feuille Aggregate pour avoir une taille de fichier inférieur à 1,5 MO

Je vous remercie par avance de votre aide et je vous souhaite un bon week-end à tous !

Prenez-soin de vous.

Laplacea

Bonjour laplacea, le forum,

Un essai.....sur la feuille "Tableau MAX".

Sub NB_Apparitions()
 Dim sh As Worksheet, plage As Range
 Dim dl As Long, i As Long

 Application.ScreenUpdating = False

  Set sh = Sheets("Aggregate")
  Set plage = sh.Range("D3:D" & sh.Range("D" & Rows.Count).End(xlUp).Row)

   With Sheets("Tableau MAX")
    dl = .Range("C" & Rows.Count).End(xlUp).Row
    .Columns("A:B").Insert Shift:=xlToRight, CopyOrigin:=xlFormatFromLeftOrAbove '...........................insert 2 colonnes à gauche
    .Range("B1") = "NB Apparitions": .Range("B1").Font.Bold = True: .Range("B1").Font.Size = 10 '............écrit NB Apparitions en B1
    .Columns("B").HorizontalAlignment = xlCenter '...........................................................texte centré horizontalement en colonne B
     For i = 2 To dl
      .Range("B" & i) = Application.WorksheetFunction.CountIf(plage, .Range("C" & i)) '......................fonction NB.SI en colonne B
     Next i
      With .Range("B2:B" & dl).FormatConditions '............................................................MFC en colonne B
       .Delete
        With .Add(xlExpression, , "=$B2<150") '..............................................................condition 1
            .Interior.Color = RGB(255, 0, 0) '...............................................................fond enrouge
            .Font.Color = RGB(255, 255, 255) '...............................................................police en blanc
        End With
        With .Add(xlExpression, , "=$B2<=250") '.............................................................condition 2
            .Interior.Color = RGB(255, 128, 0)  '............................................................fond en orange
            .Font.Color = RGB(255, 255, 255) '...............................................................police en blanc
        End With
        With .Add(xlExpression, , "=$B2>250") '................................................ .............condition 3
            .Interior.Color = RGB(0, 255, 0) '...............................................................fond en vert
            .Font.Color = RGB(255, 255, 255) '...............................................................police en blanc
        End With
      End With
   End With
End Sub

Amicalement,

Salut Xorsankukai, le forum,

Je te remercie pour ton retour.

Et ça correspond parfaitement à ce que je recherchais.

Je t'en remercie beaucoup et je reviens très vite sur le sujet : https://forum.excel-pratique.com/excel/macro-lien-extract-param-144943

Je te souhaite de passer un bon après-midi Xorsankukai !

Bien à toi.

Laplacea

Salut laplacea,

Merci pour le retour et pour avoir passé le sujet en résolu,

Je t'ai également répondu pour l'autre post,

A bientôt,

Amitiés.