Enregistrer une feuil en PDF

Hello,

J'aurais souhaiter connaitre la technique en VBA pour permettre à un utilisateur d'exporter la feuille "Rapport" en PDF dans un dossier qu'il choisira lui, en appuyant sur un bouton

Merci d'avance les potos

Julien

Bonjour Djulito,

As-tu effectué une recherche sur le forum avant de poser la question

Regarde également dans les sujet similaires

Oui j'avais regardé mais je trouvais pas la manière de faire que l'utilisateur puisse choisir l'endroit et le nom du fichier, mais je vais fouiller encore alors, j'ai peut-être mal cherché ! Désolé !

Sub Export_PDF()
Dim fichier As String

Date_F = Format(Date, "ddmmmm_")
'adaptez le nom de la feuille
With Worksheets("Feuil1")
fichier = "\" & Date_F & .Range("B7") & ".pdf"
Dossier = "C:\Users\Vincent\Documents\Commande DNA"
Chemin = Dossier & fichier
.ExportAsFixedFormat Type:=xlTypePDF, Filename:=Chemin, Quality:=xlQualityStandard, _
IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
End With
End Sub

Du coup j'ai ca... mais je n'ai pas trouvé comment l'utilisateur peut choisir le chemin et nom du fichier...

Au pire pouvoir le mettre dans le meme dossier ou se trouve le classeur.

Bon du coup je l'ai fait bêtement avec l'enregistreur et ca marche...

Re,

Pour que l'utilisateur puisse choisir le chemin et nom du fichier, tu peux faire

Sub Export_PDF()
  Dim Date_F As String
  Dim Chemin As String, Dossier As String, Fichier As String
  ' Date du jour
  Date_F = Format(Date, "ddmmmm_")
  ' Dossier
  Dossier = "C:\Users\Vincent\Documents\Commande DNA\"
  'adaptez le nom de la feuille
  With Worksheets("Feuil1")
    ' Composer le nom du fichier
    Fichier = Date_F & .Range("B7") & ".pdf"
    ' Demander le choix d'emplacement et le changement du nom (optionnel)
    Chemin = Application.GetSaveAsFilename(InitialFileName:=Dossier & Fichier, _
        FileFilter:="Fichier PDF (*.pdf), *.pdf")
    ' Exporter le fichier en PDF avec le nom choisi et l'emplacement choisi
    .ExportAsFixedFormat Type:=xlTypePDF, Filename:=Chemin, Quality:=xlQualityStandard, _
    IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
  End With
End Sub

@+

Parfait ca marche nickel merci beaucoup !