Nom de la feuille précédente par double clic

Bonjour

Est-ce possible d'adapter cette formule pour faire en sorte que le nom de la feuille précédente s'affiche uniquement lorsque j'effectue un double-clic sur la case C1 (par exemple) ? :

Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
    ActiveSheet.Range("C1").Value = Sh.Name
End Sub

Bonjour

...faire en sorte que le nom de la feuille précédente s'affiche uniquement lorsque j'effectue un double-clic sur la case C1...

Essayez avec ce code, à placer dans thisworkbook

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
If Sh.Index > 1 Then
    Cancel = False
    ActiveSheet.Range("C1") = Sheets(Sh.Index - 1).Name
End If
Cancel = True
End Sub

Cordialement

Malheureusement votre code ne permet que d'afficher le nom de la page qui la précède (dans la position), hors ce que j'aurais souhaité c'est le nom de la page précédemment affiché .

Une solution ?

Re

C'était pas expliqué comme cela dans votre demande. et vous avez déjà posé cette question ici --> https://forum.excel-pratique.com/viewtopic.php?f=2&t=140981

Mettez ces deux codes dans Thisworkbook

Dim nomfeuille As String
Private Sub Workbook_SheetActivate(ByVal Sh As Object)
nomfeuille = ActiveSheet.Name
End Sub

Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
ActiveSheet.Range("C1").Value = nomfeuille
End Sub

Comme je ne vois pas votre fichier, bien veiller à ce que la variable DIM soit bien placée à la première ligne comme ici (donc tout en haut dans thisworkbook)

Cordialement

Désolé pour le manque de précision !

Effectivement, j'avais déjà fait une demande par rapport à ça mais je pensais arriver à adapter moi-même le script mais au lieu d'appuyer sur un bouton faire simplement un double clique, malheureusement je n'y suis pas arrivé et j'ai déjà identifié le sujet comme résolu, pour ça que j'ai créé un nouveau poste .

Je viens d'essayer votre code mais malheureusement le nom de la page s'affiche automatiquement et non pas par double clique .

Je vous mets en pièce-jointe un fichier exemple de ce pourquoi j'en ai aurais besoin, ça sera peut être plus explicite

Re,

Le code à mettre dans Thisworkbook

Dim nomfeuille As String

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
If Not Intersect(Target, Range("C1")) Is Nothing Then
    Cancel = False
    Target.Value = nomfeuille
End If
Cancel = True
End Sub

Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
nomfeuille = Sh.Name
End Sub

Vous avez des codes dans chacune des feuilles que vous pouvez supprimer et le remplacer par ce code unique dans thisworkbook :

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
Dim choix
Dim f As Worksheet
choix = ""
For Each f In Worksheets
    If f.Name <> "Template" Then choix = choix & f.Name & ","
Next
With ActiveSheet.Range("C1").Validation
    .Delete
    .Add xlValidateList, Formula1:=choix
End With
End Sub

Cordialement

Merci beaucoup !

C'est parfaitement ce que je recherchais !!