Associer un tarif à une checkbox

Bonsoir le forum,

Comme l'indique le sujet, je voudrais associer des tarifs à mes checkbox, et réussir par la même occasion à les additionner.

Je débute avec le VBA, mais avec le confinement, j'en profite pour apprendre.

J'utilise excel 2019 en 64bits sous windows

checkbox1 30,00€

checkbox2 20,00€

checkbox1 + checkbox2 = 50,00€ en Label 11

Je ne recherche pas que la réponse, je voudrais aussi que l'on m'explique.

Merci d'avance

Bonjour benoit06190

Associer des tarifs à des checkbox... qu'elle drôle d'idée

J'espère que tu n'en as pas des dizaines....

Ceci dit, voici un code

Private Sub CheckBox1_Click()
  Call MàJ_Tarif
End Sub

Private Sub CheckBox2_Click()
  Call MàJ_Tarif
End Sub

Sub MàJ_Tarif()
  Dim Total As Single, sPx As String, Prix As Single
  Dim Ctr As Control
  ' Pour chaque control du UserForm
  For Each Ctr In Me.Controls
    ' Si le control est un Checkbox
    If TypeName(Ctr) Like "CheckBox*" Then
      ' Récupérer le texte de la checkbox
      sPx = Ctr.Caption
      ' Supprimer le signe €
      sPx = Replace(sPx, "€", "")
      ' Suprimer les espaces éventuels
      sPx = Replace(sPx, " ", "")
      ' Récupérer la valeur du texte
      Prix = CSng(sPx)
      If Ctr.Value = True Then
        ' Additionner au total
        Total = Total + Prix
      End If
      ' Indiquer le montant dans le label11
      Me.Label11.Caption = Format(Total, "#,##0.00€")
    End If
  Next
End Sub

A+

Bonjour,

Tu espères que j'en ai pas des dixaines à faire, tu parles des formules ou de mes drôles d'idées.

Merci beaucoup.

C'est vrai qu'il y avait beaucoup plus simple, la nuit porte conseil .

Merci encore, et te souhaite une bonne continuation