Selection d'une ligne à partir d'une cellule avec conditions

Bonjour,

j'ai besoin de votre aide pour faire sélectionner une ligne à partir d"une cellule avec des conditions.

J'ai une feuille avec des lignes de données, L'objectifs est de sélectionner une seule cellule de colonne A ensuite en cliquant sur "ad"

un userform s'affichera pour confirmer mon choix.

Pour cela j'ai deux conditions qui vont permettre l'ouverture de l'userform :

Condition 1 : je peux sélectionner qu'une seule cellule de la colonne A ( possibilité de faire la conditions avec la différence de couleur )

Conditions 2 : Si je sélectionne une cellule et que cette cellule correspond à une ligne vide ( sans informations) alors un message apparaîtra " merci de vérifier votre sélection "

Merci

Bonjour bibo007, le forum,

Un essai......

Sub ouverture()

 Dim lig As Integer, plage As Range
         lig = ActiveCell.Row                      'définit la ligne suivant la cellule selectionnée
   Set plage = Range("A" & lig & ":E" & lig)       'définit la plage de A à E en fonction de la ligne

  If Selection.Count > 1 Then MsgBox "Veuillez selectionner une seule case": Exit Sub          'si plus d'une cellule selectionnée
   If Selection.Column > 1 Then MsgBox "La selection doit se faire en colonne A": Exit Sub     'si ce n'est pas en colonne A
    If Application.CountA(plage) = 0 Then MsgBox "Merci de vérifier votre selection": Exit Sub 'si la ligne est vide

  UserForm1.Show

End Sub

Cordialement,

Bonjour Bibo, bonjour le forum,

En pièce jointe ton fichier dans lequel j'ai supprimé le bouton AD. L'action se fait automatiquement en double-cliquant sur une cellule. L'avantage est que le double-clic ne peut se faire que dans une cellule et qu'il évite d'aller cliquer sur un bouton.

le code commenté (qui se trouve dans le composant VBA Feuil1(Sheet1) :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Column <> 1 Then Exit Sub 'si le double-cli a lieu ailleurs que dans la colonne 1 (=A), sort de pa procédure
Cancel = True 'évite le mode [Édition] lié au double-clic
'si la cellule adjacente est vide, message, sort de la procédure
If Target.Offset(0, 1).Value = "" Then MsgBox "Merci de vérifier votre sélection !": Exit Sub
UserForm1.Show 'lance l'UserForm1
End Sub

Le fichier :

[Édition]

Bonjour xorsankukai, nos posts se sont croisé...

Cela me convient parfaitement.

Merci beaucoup à @ThauThème et @ xorsankukai pour votre aide et votre réactivité.

Autre questions svp : comment puis-je trouver les informations des cellules dans les textBox de l'userform ?

Merci d'avance

Re,

Bonsoir Thauthème

@ bibo007 :

Merci pour ton retour,

comment puis-je trouver les informations des cellules dans les textBox de l'userform ?

Et elles sont où tes Textbox ?

A tester....

Private Sub UserForm_Initialize()
 Dim lig As Long
  With Sheets("Sheet1")
   lig = ActiveCell.Row
    Me.TxtTechnologie = .Range("B" & lig)
    Me.TxtPuissance = .Range("C" & lig)
    Me.TxtMatériaux = .Range("D" & lig)
    Me.TxtPrix = .Range("E" & lig)
  End With
End Sub

Bonne soirée,

Top merci beaucoup @xorsankukai, tu me sauves la vie haha !!