Macro pour vérifier un élément nouveau dans la liste

bonjour

J'ai une feuille "utilisateurs" où sont inscrits les numéros des vendeurs .......dans la feuille 2 "BD_CLMT je vais copier quotidiennement un fichier avec plus de 2000 lignes...je cherche une macro qui me permet de vérifier s'il y a un nouveau vendeur qui apparaît et qui ne figure pas dans la liste figurant dans la feuille "utilisateurs". Le but est de le dénicher et l'ajouter à la liste.

Merci

Bonjour,

Une piste :

Sub Test()

    Dim FeUtil As Worksheet
    Dim FeBD As Worksheet
    Dim PlgUtil As Range
    Dim PlgBD As Range
    Dim CelUtil As Range
    Dim CelBD As Range
    Dim Lig As Long
    Dim Message As String

    Set FeUtil = Worksheets("Utilisateurs")
    Set FeBD = Worksheets("BD_CLMT")

    With FeBD: Set PlgBD = .Range(.Cells(2, 10), .Cells(.Rows.Count, 10).End(xlUp)): End With
    With FeUtil: Set PlgUtil = .Range(.Cells(2, 8), .Cells(.Rows.Count, 8).End(xlUp)): End With

    For Each CelBD In PlgBD

        Set CelUtil = PlgUtil.Find(CelBD.Value, , xlValues, xlWhole)

        If CelUtil Is Nothing Then

            Lig = FeUtil.Cells(Rows.Count, 8).End(xlUp).Row + 1
            FeUtil.Cells(Lig, 8).Value = CelBD.Value
            FeUtil.Cells(Lig, 7).Value = CelBD.Offset(, -4).Value
            Message = Message & "'" & CelBD.Value & "' pour le point de vente '" & CelBD.Offset(, -4).Value & "'" & vbCrLf

        End If

    Next CelBD

    If Message <> "" Then MsgBox "Le ou les vendeurs ci-dessous ont été ajoutés à la liste : " & vbCrLf & Message

End Sub

Merci beaucoup Theze ....il me liste exactement les vendeurs ajoutés

comment il va connaitre le point où ils seront affectés ? ça va poser problèmes car il y a uniquement 9 points de vente

ah oui j'ai compris maintenant.....il est ajouté en fonction du numéro de point de vente....oui c'est parfait ça me va très bien

Merci infiniment

Bonjour,

Content de t'avoir aidé

Re-bonjour

Est quand il y a pas de nouveaux vendeurs ajoutés, on peut recevoir le message MsgBox "pas de nouveaux vendeurs ajoutés"

Merci d'avance

Bonjour,

En lieu et place de cette ligne de code :

If Message <> "" Then MsgBox "Le ou les vendeurs ci-dessous ont été ajoutés à la liste : " & vbCrLf & Message

tu mets celles-ci :

If Message <> "" Then

    MsgBox "Le ou les vendeurs ci-dessous ont été ajoutés à la liste : " & vbCrLf & Message

Else

    MsgBox "Il n'y a aucun nouveau vendeur dans la liste !"

End If