Récupération de donnés d'une colonne entiere sans vides ni doublons

bonjour tout le monde,

j'ai vraiment besoin de votre aide svp.

je suis nouvelle dans le forum.

je débute en vba , je suis autodidacte , mais je rencontre un soucis,

j'ai deux fichiers excel ADD1 et ADD2 chacun a plusieurs feuilles avec plusieurs colonnes, j'aimerai pouvoir récupérer toutes les cellules de la colonne E de la feuille 2 du fichier ADD1 vers la colonne H de la feuille4 du fichier ADD2.

le problème est que je dois créer un bouton pour récupérer une à une les cellules en supprimant les vides et les doublons.

on me suggère d'utiliser des boucles mais mon code ne marche pas.

j'ai regardé bcp de suggestions de code dans le forum, mais c'est soit pour supprimer les doublons seulement soit pour éliminer les vides seulement. moi je faire les deux à la fois

PS: je ne peux pas joindre le fichier mon employeur me l'interdit.

merci d'avance pour toute réponse.

Bonjour,

Une piste, voir les commentaires et faire les adaptations :

Sub Test()

    Dim ClsADD1 As Workbook
    Dim ClsADD2 As Workbook
    Dim Dico As Object
    Dim Plage As Range
    Dim Cle As Variant
    Dim Cel As Range
    Dim I As Long

    Set ClsADD1 = Workbooks("ADD1.xlsm") 'adapter les noms et extensions !
    Set ClsADD2 = Workbooks("ADD2.xlsm")

    Set Dico = CreateObject("Scripting.Dictionary")

    'adapter le nom de la feuille
    With ClsADD1.Worksheets("Feuil2"): Set Plage = .Range(.Cells(1, 5), .Cells(.Rows.Count, 5).End(xlUp)): End With

    For Each Cel In Plage

        If Cel.Value <> "" Then Dico(Cel.Value) = ""

    Next Cel

    For Each Cle In Dico.Keys

        I = I + 1
        'adapter le nom de la feuille
        ClsADD2.Worksheets("Feuil4").Cells(I, 8).Value = Cle

    Next Cle

End Sub

bonjour,

Theze ton code marche super bien . J'ai juste fait les adaptations et ça marche trop bien , j'ai eu tout ce que je voulais .

je vous remercie beaucoup Theze.

merci aussi à galopin01.

Je vous remercie pour votre disponibilité à tous les deux.

Bonjour,

Parfait, content de t’avoiR aidé