Exporter 5 onglets sur 7 en CSV (sép. par

Question

Bonjour à toutes & tous,

D'avance merci pour l'aide que vous voudrez bien m'apporter.

J'ai fait un bon de commande pour la force de vente. Il y a 7 onglets.

Le premier, c'est le bon de commande.

Le deuxième, la base clientèle dont je me sers pour renseigner les infos du bon de commande.

Puis, les 5 suivants recopie les données utiles du bon de commande en vu d'exporter l'onglet en csv séparé par des ";".

Il y a 5 onglets car j'ai 5 cadences de livraisons.

Pouvez vous m'aider à automatiser l'exportation des 5 onglets en CSV dans un dossier à choisir ?

J'exporte en csv (;) dans le but de les importer dans notre logiciel interne.

Encore merci pour votre aide.

Nicolas

Office 365 MSO (16)

m3ellem1 · Answer

Slt Nicolas,

à tester:

Sub ExportCSV_Choix_Chemain()
    Dim sh As Worksheet
    Dim xcsvFile As String
    Dim strFolder As String

    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "Selectionner la destination"
        If .Show Then
            strFolder = .SelectedItems(1)
        Else
            Beep
            Exit Sub
        End If
    End With

    If Right(strFolder, 1) <> "\" Then
        strFolder = strFolder & "\"
    End If

    For Each sh In Application.ActiveWorkbook.Worksheets
    If sh.Name <> "Fueil1" And sh.Name <> "Fueil2" Then ' changer les noms des 2 feuilles à exclure d'export
        sh.Copy
        xcsvFile = strFolder & sh.Name & ".csv"
        Application.ActiveWorkbook.SaveAs Filename:=xcsvFile, _
        FileFormat:=xlCSV, CreateBackup:=False, local:=True
        Application.ActiveWorkbook.Saved = True
        Application.ActiveWorkbook.Close
    End If
    Next
End Sub