Message d'alerte vers outlook

Bonjour

j'ai un petit problème avec excel et mon petit niveau en excel n'aide pas

dans ma feuille de calcul , j'ai deux colonnes une avec les noms des personnes devant effectuer des vérifications et dans l'autre colonne , le nombre de jour qui reste avant de faire une nouvelle vérification

je voudrais envoyer un mail via outlook des que l'échéance arrive 0 ,pouvez vous m'aider svp

merci d'avance

Bonjour à toi black_hawk, forum

Peux-tu envoyer un bout de fichier avec la structure exacte de tes données? Tu peux mettre des données bidons mais en gardant ce qui nous permettra de trouver une solution.

On pourra peut-être adapter la solution se trouvant à cette adresse : http://www.tek-tips.com/faqs.cfm?fid=3564

en fait en colonne A , il y a differentes vérifications à faire en colonne B il y a le nom des personnes faisant ces vérifications , en colonne C il y a la date de la dernière vérification avec en colonne D la périodicité de ces vérifications et en colonne E le nombre de jours restant avant la nouvelle vérification

et je voudrais envoyer a la personne qui se trouve par exemple sur la ligne 2 un mail automatique des que le nombre de jours est de 0

merci d'avance

Re,

J'ai bien compris la structure, mais sans fichier, pas facile de trouver une solution adaptée.

Essaie tout de même ça :

1. Ouvre l'éditeur visual basic (VBE) en appuyant sur ALT+F11

2. Dans 'Outils' -> 'Références' -> Coche Microsoft Outlook 11.0 Object Library (ou un truc qui y ressemble)

3. Double-clique sur 'ThisWorkbook' et colle le code suivant :

Private Sub Workbook_Open()
Dim i As Long
Dim dest As String

For i = 1 To Range("E65000").End(xlUp).Row
        dest = Cells(i, 2)
    If Cells(i, 5) = 0 Then
        Call MailAuto(dest)
    End If
Next i

End Sub

4. Insère un nouveau module en faisant un clic droit sur 'ThisWorkbook' -> Insertion -> Module, puis colle le code suivant :

Sub MailAuto(dest As String)

Dim bStarted As Boolean
Dim oOutlookApp As Outlook.Application
Dim oItem As Outlook.MailItem

On Error Resume Next

'Teste si une instance d'Outlook est déjà ouverte
Set oOutlookApp = GetObject(, "Outlook.Application")
If Err <> 0 Then
    'Outlook non ouvert, lancement d'une instance à partir du code
    Set oOutlookApp = CreateObject("Outlook.Application")
    bStarted = True
End If

'Crée un nouveau mail
Set oItem = oOutlookApp.CreateItem(olMailItem)

With oItem
    'Destinataire du mail
   .To = dest
    'Définit un mail en copie cachée
    .CC = "tonmail@mail.com"
    'Définit le sujet
    .Subject = " "
    'Le contenu du document est utilisé comme corps d'email
    .Body = "Bonjour" & vbCrLf & "Veuillez trouver ci-joint le contrat demandé." & vbCrLf
    'Pour attacher une pièce jointe
    .Attachments.Add Source:="G:\titi.xls"
'Send permet d'envoyer le mail
    .Send 'Display
End With

If bStarted Then
    'Si Outlook est lancé depuis le code, on le ferme (??!)
    oOutlookApp.Quit
End If

'Nettoie les variables
Set oItem = Nothing
Set oOutlookApp = Nothing

End Sub

merci je vais essayer de me dépatouiller avec ça , merci beaucoup

Après quelques modifications et quelques jours de congé , le fichier exécute l'application

merci pour ta réponse , ta solution marche merci