Ignorer et ne pas afficher un message d'information

Question

Je me demandais s'il était possible de ne pas afficher un message d'information et d'ignorer ce message. J'ai créé une connexion entre fichiers. Cette connexion est rafraîchie toutes les demie-heures.Le problème est quand le fichier dans le lequel le récupère des données, est ouvert, la connexion ne peut pas se faire, et le message suivant apparaît: Comme ce tableau est envoyé sur un écran à destination de mes collègues, ils se retrouvent souvent face à ce message qui les empêche de voir ce qu'il y a en dessous... J'aimerai donc que ce message ne s'affiche pas et que le rafraîchissement se fasse un plus tard ou la demie-heure. Voici le code utilsé: Public Sub actu() Dim wks As Worksheet Dim wkb As Workbook Set wkb = Workbooks("Visu_générale.xlsm") Set wks = wkb.Worksheets("Graphique") wkb.Worksheets("donnée").ListObjects(1).Refresh wkb.Worksheets("Archives").ListObjects(1).Refresh Call Module4.tab_blanc(wkb) Call Module1.dessiner(wkb) End Sub End Sub Si quelqu'un a une idée. Merci !!! Jojo la frite...

MFerrand · Answer

Essaie avec un : Application.DisplayAlerts = False Cordialement...

dhany · Answer

Bonsoir jojo , quand j'ai vu la solution donnée par MFerrand , j'm'étais dit qu'ça devait être ça ! mais peut-être n'as-tu pas mis cette instruction au bon endroit ? moi, je l'aurais placée juste avant le 1er .Refresh, ainsi : Public Sub actu() Dim wkb As Workbook Dim wks As Worksheet Set wkb = Workbooks("Visu_générale.xlsm") Set wks = wkb.Worksheets("Graphique") Application.DisplayAlerts = False wkb.Worksheets("donnée").ListObjects(1).Refresh wkb.Worksheets("Archives").ListObjects(1).Refresh Application.DisplayAlerts = True Module4.tab_blanc wkb Module1.dessiner wkb End Sub tu avais mis un 2ème « End Sub » en trop, que j'ai enlevé ; et c'est plus naturel de déclarer wkb avant wks. tu auras aussi noté qu'après les 2 .Refresh, j'ai réactivé les alertes : j'crois qu'c'est plus sûr. si ça marche comme tu veux, merci d'passer l'sujet en résolu ; sinon, indique plus précisément c'qui va pas : ton « mais malheureusement ça ne marche pas.... » est bien trop vague pour pouvoir t'aider ! donc : * si y'a un message d'erreur, quel est le texte exact de ce message d'erreur ? * si y'a une ligne mise en jaune dans le code VBA, laquelle est-ce ? * quel résultat as-tu qui est autre que celui attendu ? mais rassure-toi : t'as pas besoin d'raconter toute ta vie depuis ta plus tendre enfance ! sers-nous plutôt des frites. dhany...

eriiic · Answer

Une fonction qui te permet de savoir si ton classeur est disponible : Sub Test() Dim i As Integer i = VerifClasseur("C:\Transfert\Test.xls") Select Case i Case 0: MsgBox "Classeur fermé." Case 53: MsgBox "Fichier introuvable" Case 70: MsgBox "Classeur déja ouvert." Case Else: MsgBox "Erreur : " &amp; i End Select End Sub Private Function VerifClasseur(Fichier As String) As Integer Dim x As Integer On Error Resume Next x = FreeFile() Open Fichier For Input Lock Read As #x Close x VerifClasseur = Err.Number On Error GoTo 0 End Function Ton sub Actu pourrait se relancer lui--même x min plus tard (3 si fichier occupé, 30 si libre) avec Ontime (voir l'aide vba avec exemple) Si tu fais ce choix il faudrait programmer le 1er lancement sur workbook_open, et annuler le prochain (à mémoriser) sur workbook_close eric...

eriiic · Answer

Heuuuu, tu as fait n'importe quoi là... Etonné même que ça fonctionne comme tu l'entends eric...

eriiic · Answer

Tu n'as pas besoin de répéter x fois le select case, un seul fichier ouvert suffit à dire niet.

Ou bien, si tu veux garder tes j=..., k=..., l=... tu les fais tous à la suite,

et un If j OR k OR l Then te dit si tu es non ok ou ok, avec un seul traitement pour chaque cas.

Il faut traiter toutes les anos. Sinon si un fichier a disparu, tu entreras dans une boucle sans fin => plantage.

Les Goto rendent le code très difficile à maintenir.

VBA a toutes les structures permettant de s'en passer (presque tout le temps), à utiliser seulement pour les traitements d'erreur.

J'imaginais plus les choses comme ça :

' ThisWorkbook
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Stop_Horloge_Visu_Ge
End Sub

Private Sub Workbook_Open()
    supervise
End Sub

' module Standard
Dim nexttime As Date

Sub supervise()
    Dim i As Integer
    Stop_Horloge_Visu_Ge
    'Pour éviter le message d'erreur, on vérifie q'un des 3 fichiers charges_planifiée n'est pas ouvert
    For i = 1 To 3
        Select Case VerifClasseur("C:\Users\kaspa\Desktop\gestion fours\Sections_séparées\Charges_Planifiées_Sections_Séparées\charge_planifiée" & i & ".xlsm")
        Case 0    ' Classeur fermé.
        Case 70    ' Classeur ouvert
            nexttime = Now + TimeValue("0:02")
            Application.OnTime EarliestTime:=nexttime, Procedure:="supervise"
            Exit Sub
        Case Else:    ' autre Erreur
            MsgBox "Anomalie fichier 'charge_planifiée" & i & ".xlsm'"
            Exit Sub
        End Select
    Next i
    ' fichiers ok
    actu
    nexttime = Now + TimeValue("0:30")
    Application.OnTime EarliestTime:=nexttime, Procedure:="supervise"
End Sub

Public Sub Stop_Horloge_Visu_Ge()
    On Error Resume Next
    Application.OnTime EarliestTime:=nexttime, Procedure:="supervise", Schedule:=False
End Sub

Private Function VerifClasseur(Fichier As String) As Integer
    Dim x As Integer
    On Error Resume Next
    x = FreeFile()
    Open Fichier For Input Lock Read As #x
    Close x
    VerifClasseur = Err.Number
    On Error GoTo 0
End Function

Sub actu()
 '...
End Sub

Et pour un lancement manuel tu appelles supervise. (d'où le Stop_Horloge_Visu_Ge au début, pour ne pas en avoir 15 en attente).

A faire également après une anomalie autre que 'fichier ouvert' pour relancer le bouzin.

Bien sûr je n'ai pas pu tester. Malgré une relecture attentive il reste peut-être des erreurs...

eric

eriiic · Answer

Tu peux. Mais, quand c'est possible, découper son code en fonctions bien précises est une bonne habitude à prendre. Une fois chaque partie bien testée et déboguée tu sais que tu n'as plus à revenir dessus. Et ça facilite la lecture quand tu dois le faire évoluer 6 mois plus tard. eric...