Afficher les douze mois

bonsoir a tous et toutes, forum bonsoir,

Voila je souhaiterai en VBA svp dans la plage D2:O2 afficher par une petite boucle les douzes mois de l'année sous cette forme si possible.

D2 = Janv 09 avec majuscule gras et rouge

E2 = Févr 09 idem

F2 = Mars 09 idem

etc...etc

Merci a vous et de votre temps

Bonne soirée a tous et merci d'avance

Raymond

Bonsoir,

Supprimé, un bug

Edit, non, encore un bug

Bonsoir Felix bonsoir forum

Merci beaucoup pour ta réponse, ,je te promets que je passe un temps fou a chercher sur le net et sur pleins de forum des codes qui peuvent m'aider.

Je me rends compte que je m'y prends comme un manche pour poser les bonnes questions, je n'arrive pas souvent a de bon résultat, enfin je persévère.

Mais j'avoue aussi qu'a 57 ans j'ai un peu de mal a enregistrer

apparament ton code marche presque mais regarde sept oct nov c'est pas bon

et si possible SVP premiere lettre en majuscule rouge et gras le reste noir normal, la tout s'affiche ne rouge gras

Janv 09 Févr 09 Mars 09 Avr 09 Mai 09 Juin 09 Juil 09 Août 09 sept.-09 oct.-09 nov.-09 Déc 09

je n'ai pas encore beaucoup d'experience mais ca va le faire

en tout cas merci a toi a plus tard bonne soirée

Raymond

Bonsoir,

Voici une solution :

    Dim intMois As Integer

    For intMois = 1 To 12
        With Cells(2, 3 + intMois)
            .NumberFormat = "@"
            .Value = Application.WorksheetFunction.Proper(Format("01/" & intMois, "mmm")) & " " & Right(CStr(Year(Now)), 2)
            With .Font
                .Bold = True
                .ColorIndex = 3
            End With
        End With
    Next intMois

Bonsoir,

J'ai fais ceci pour mon boulot,regarde et adapte le .

https://www.excel-pratique.com/~files/doc2/Calendrier_12_mois.zip

A +

Salut le forum

Readi un simple Dim intMois As Byte aurait suffit.

Il n'a a pas 32767 mois dans l'année quand même.

Mytå

Bonjour a tous et toutes, forum bonjour

j'ai réussi a afficher mes douze mois avec VOS codes et conseil de Myta

Juste un petit truc SVP, sur le code de Readi, je n'arrive pas a repasser APRES la majuscule, les minuscules en noir pour chacun des 12 mois bien sur

Merci a tous de votre aide bonne journée, vais faire un petit café

Raymond

Bonjour

Sub mois()

    Dim intMois As Byte

    For intMois = 1 To 12
        With Cells(2, 3 + intMois)
            .NumberFormat = "@"
            .Value = Application.WorksheetFunction.Proper(Format("01/" & intMois, "mmm")) & " " & Right(CStr(Year(Now)), 2)
            With .Font
                .Bold = True
             '   .ColorIndex = 3
            End With
         With .Characters(Start:=1, Length:=1).Font
            .ColorIndex = 3
         End With
        End With
    Next intMois

End Sub

Regarde si cela te convient?

Bonjour Bruno, Re forum

Merci pour ta réponse, c'est sympa, je viens d'essayer ton code mais tout reste en rouge gras.

Suis sur excel 2007 peut etre, j'ai essayer de modifier mais sans résultat, bon j'y retourne me laisse pas abattre, non mais.

A plus tard et une bonne journée a toi

Raymond

Bonjour,

Une autre version :

Sub mois()
    Dim byMois As Byte

    For byMois = 1 To 12
        With Cells(2, 3 + byMois)
            .ClearFormats
            .NumberFormat = "@"
            .Value = Application.WorksheetFunction.Proper(Format("01/" & byMois, "mmm")) & " " & Right(CStr(Year(Now)), 2)
            .Font.Bold = True
            .Characters(Start:=1, Length:=1).Font.ColorIndex = 3
        End With
    Next byMois
End Sub

N'ayant pas Excel 2007, je ne sais pas si cela fonctionne sous cette version.

Salut readi, forum

Merci pour la réponse et le code, te confirme que ca fonctionne sous XL 2007, a part que l'affichage ne repasse pas en écriture NON gras après chaque majuscule, sinon c'est tout bon.

Merci je vais essayer de voir si j'arrive a faire ca

Bonne journée a toi

Raymond

re,

Voici une autre solution :

Sub mois()
    Dim byMois As Byte

    For byMois = 1 To 12
        With Cells(2, 3 + byMois)
            .ClearFormats
            .NumberFormat = "@"
            .Value = Application.WorksheetFunction.Proper(Format("01/" & byMois, "mmm")) & " " & Right(CStr(Year(Now)), 2)
            '.Font.Bold = True
            With .Characters(Start:=1, Length:=1).Font
                .ColorIndex = 3
                .Bold = True
            End With
        End With
    Next byMois
End Sub

Re Readi Forum

Merci beaucoup Merci beaucoup, c'est bon ca marche comme attendu sur XL 2007, je n'ai plus qu'a intégrer le code dans mon programme.

Encore merci pour le coup de main, c'est super sympa

Je te souhaite un excellent W-end

A part ce code que je pige pas ( .NumberFormat = "@" ) mais c'est pas grave

Bye Bye

Raymond

re,

.NumberFormat = "@" : définir la cellule au format Texte

Je te souhate également un bon week end.