Calculer la moyenne d'après certaines tranche horaires
Bonjour le forum,
Sur le fichier joint, nous avons un fichier qui reprend en colonne A, des dates à un format personnalisée ( exemple : 26/03/2018 11: 00 ), et des données de températures en colonne B.
Les données du format personnalisée (Col A) apparaissent à chaque ligne avec un pas incrémentée de 10 minutes . du lundi 11h au dimanche 23h50.
ce que je souhaiterai, c'est à partir d'une plage horaire demandée, ( voir cellules D2:E2 sur l'exemple joint ), de calculer la moyenne des températures contenues dans ces plages horaires du lundi au vendredi uniquement.
En sachant que ces plages horaires ne sont jamais les mêmes d'une semaine à l'autre.
Je pense qu'il faut arriver à isoler l'horaire, mais avec le format personnalisé, je n'arrive à pas grand chose pour l'instant.
Si quelqu'un peut y jeter un œil, je l'en remercie par avance;
Mamarus
Bjr,
attention arrondis des valeurs de base sans doute
=SOMMEPROD((MOD(A3:A944;1)>=$D$2)*(MOD(A3:A944;1)<=$E$2)*(B3:B944))/SOMMEPROD((MOD(A3:A944;1)>=$D$2)*(MOD(A3:A944;1)<=$E$2))cela n'a pas d'influence !Je pense qu'il faut arriver à isoler l'horaire, mais avec le format personnalisé, je n'arrive à pas grand chose pour l'instant.
où se trouvent ces valeurs ?En sachant que ces plages horaires ne sont jamais les mêmes d'une semaine à l'autre.
Bonjour Steelson,
Merci de s'être intéressé à mon problème, à la question ou se trouvent ces valeurs ? , en fait c'est la plage des températures ( colonne B ).
Dans la formule, je pense que tu as pris en plage de données l'ensemble de la semaine, moi cela doit s'arrêter au vendredi, il suffit de le modifier les champs dans la formule je suppose.
Par ailleurs, j'aurai à extraire aussi toujours d'après ces 2 plages horaires, la valeur maxi de température se trouvant dans celle ci.
Merci par avance;
Mamarus
=SOMMEPROD((JOURSEM(A3:A944;2)<6)*(MOD(A3:A944;1)>=$D$2)*(MOD(A3:A944;1)<=$E$2)*(B3:B944))/SOMMEPROD((JOURSEM(A3:A944;2)<6)*(MOD(A3:A944;1)>=$D$2)*(MOD(A3:A944;1)<=$E$2))à vérifier pour le max :
=MAX((JOURSEM(A3:A944;2)<6)*(MOD(A3:A944;1)>=$D$2)*(MOD(A3:A944;1)<=$E$2)*(B3:B944))Re Bonjour,
j'ai vérifié pour le Maxi, cela marche parfois , mais pas tout le temps, par exemple si on prend dans le fichier exemple, la plage de 11:40 à 12:40, le montant en max affiché est celui de 11:50 à 22.5428, alors que le vrai max est celui de 11:40 à 22.7466.
Je ne saurai dire pourquoi, à moins que l'on soit en format personnalisé, mais j'y crois pas de trop.
Mamarus
Bonjour Mamarus, Steelson, à tous,
J'ai essayé plusieurs versions de formule sans obtenir de résultat juste,
il me reste la formule MOYENNE.SI.ENS à vérifier,
mais j'ai de la difficulté lorsque j'essaie de valider la formule j'obtiens :ERREUR: "La formule que vous avez tapée contient une erreur."
J'ai beau chercher je ne vois plus rien
Edit:
correction sur la formule Moyenne(si
j'ai vérifié pour le Maxi, cela marche parfois , mais pas tout le temps, par exemple si on prend dans le fichier exemple, la plage de 11:40 à 12:40, le montant en max affiché est celui de 11:50 à 22.5428, alors que le vrai max est celui de 11:40 à 22.7466.
Je ne saurai dire pourquoi, à moins que l'on soit en format personnalisé, mais j'y crois pas de trop.
Ce n'est pas dû au format personnalisé.
C'est une question de précision d'enregistrement des données.
cf image ci-dessous
La moyenne comporte aussi un biais, mais comme c'est la moyenne cela ne se voit pas.
solution : mettre 11:39 !!
@mamarus
une autre façon de résoudre ce problème de précision d données (encore une fois le format d'affichage n'influence pas), c'est de mettre comme borne une donnée "équivalente", par exemple 01/01/2018 11:40 et de mettre la fonction MOD de part et d'autre de la formule, je ne sais pas si je suis assez clair ?
bon, je pense qu'il y a une autre raison sur le max,
je vais continuer à investiguer car quand je passe en matriciel par Ctrl+Maj+Entrée, je trouve autre chose !!
Bonjour Steelson,
Merci pour l'investissement, je me doutais que cela ne serait pas si simple.
Mamarus
voici avec une formule matricielle
maintenant ton 26/03/2018 11:40 n'est pas tout à fait ... 26/03/2018 11:40
retape le dans la case et tu auras bien 22,7466716766357 comme maxi
Bonjour à tous,
le calcul de la moyenne est juste avec la formule matricielle suivante,
=MOYENNE(SI((JOURSEM(dt;2)<=5)*(TEMPS(HEURE(dt);MINUTE(dt);SECONDE(dt))>=F1)*(TEMPS(HEURE(dt);MINUTE(dt);SECONDE(dt))<=G1);tp))j'aurais voulu faire ce calcul également avec la fonction MOYENNE.SI.ENS
=MOYENNE.SI.ENS(tp;TEMPS(HEURE(dt);MINUTE(dt);SECONDE(dt));">="&F1;TEMPS(HEURE(dt);MINUTE(dt);SECONDE(dt));"<="&G1)mais cette formule contient une erreur que je n'arrive pas à trouver.
Bonjour,
@ Isabelle,
Cette fonction requiert des plages pour les critères.
TEMPS(HEURE(dt);MINUTE(dt);SECONDE(dt)) n'est pas une plage ! ...
Cdlt.
Bonjour à tous,
@Jean-Eric
merci pour cet info.
en regardant les matrices "Plage_critère" lors de la création de la formule, cela porte à confusion
RE,
On est bien d'accord ! ...
Une plage et non une matrice ({...}.
Je pense que c'est comme SOMMEPROD, une matricielle sans Ctrl+Maj et Entrée.
Cdlt.
Je pense que c'est comme SOMMEPROD, une matricielle sans Ctrl+Maj et Entrée.oui c'est ce que je croyais aussi, Excel comprend de quoi il s’agit, on voit bien en regardant à droite vis-à-vis chaque argument,
chaque matrice résultante est sous la même forme {1, 2, 3…}
que ce soit pour "Plage_moyenne" ou "Plage_critère"
donc Excel est capable d’évaluer chaque argument, mais est incapable de comprendre la formule.
La personne qui a écrit le code de MOYENNE.SI.ENS a du oublier quelque chose…