Alerte outlook via fichier Excel

James007 a écrit :

Steelson a écrit :

oui, c'est en cours, un dernier test et j'envoie

Salut Michel

Je trouve que tu pourrais cravacher un peu plus vite ...

hey, j'avais pas vu ... bon tu as peut-être raison, mais faut aussi que je décompresse un peu !

sans outlook, c'est un peu comme un funambule sans balancier ...

GESTIONNAIRES est bien en majuscule

Les noms des onglets sont identiques à la feuille GESTIONNAIRES

On ne voit pas où est le problème

Notre responsable nous a donné l'accord pour vous envoyer notre fichier. Est ce possible?

Merci

K-DO45 a écrit :

Notre responsable nous a donné l'accord pour vous envoyer notre fichier. Est ce possible?

Bonjour,

Pas de problème ...

K-DO45 a écrit :

GESTIONNAIRES est bien en majuscule

Les noms des onglets sont identiques à la feuille GESTIONNAIRES

On ne voit pas où est le problème

Notre responsable nous a donné l'accord pour vous envoyer notre fichier. Est ce possible?

Merci

en MP

envoie seulement la feuille "gestionnaires", même une seule photo de celle-ci que je voie

regarde aussi qu'il n'y ait pas d'espace dans la liste des onglets à côté des gestionnaires

Merci James pour ta proposition d'aide

L'erreur se situe bien au niveau du nom d'un onglet

Remplace module1 en VBA par ceci :

Le programme indiquera quelle feuille n'existe pas le cas échéant.

Option Explicit
Sub alerter()
Dim messagerie As Object
Dim email As Object
Dim cel As Range
Dim txt As String
Dim ws As Worksheet

Set messagerie = CreateObject("Outlook.Application")

Dim i, j, qui
With Sheets("GESTIONNAIRES")
    For i = 2 To .Cells(Application.Rows.Count, 1).End(xlUp).Row
        qui = .Cells(i, 1)
        txt = "<table>"
        For j = 2 To .Cells(i, 1).End(xlToRight).Column
            If FeuilleExiste(.Cells(i, j).Value) = False Then
                MsgBox "La feuille """ & .Cells(i, j).Value & """ n'existe pas !"
                Exit Sub
            End If
            Set ws = Sheets(.Cells(i, j).Value)
            ws.Select
            txt = txt & "<tr><td><b>" & ws.Name & "</b></td></tr>"
            Set cel = Range("A14")
            txt = txt & "<tr><td>" & _
            cel.Offset(0, 0) & "</td><td>" & _
            cel.Offset(0, 1) & "</td><td>" & _
            cel.Offset(0, 3) & "</td><td>" & _
            cel.Offset(0, 9) & "</td><td>" & _
            cel.Offset(0, 15) & "</td><td>" & _
            cel.Offset(0, 20) & "</td><td>" & _
            cel.Offset(0, 27) & "</td><td>" & _
            "</td></tr>"
            For Each cel In Range("A15:A" & Range("A14").End(xlDown).Row)
                If cel.Offset(0, 27) < Now + 15 And cel.Offset(0, 27) > Now Then
                    cel.Offset(0, 34) = Now
                    txt = txt & "<tr><td>" & _
                    cel.Offset(0, 0) & "</td><td>" & _
                    cel.Offset(0, 1) & "</td><td>" & _
                    cel.Offset(0, 3) & "</td><td>" & _
                    cel.Offset(0, 9) & "</td><td>" & _
                    cel.Offset(0, 15) & "</td><td>" & _
                    cel.Offset(0, 20) & "</td><td>" & _
                    cel.Offset(0, 27) & "</td><td>" & _
                    "</td></tr>"
                End If
            Next cel
        Next
        txt = txt & "</table>"
        'Debug.Print txt
        Set email = messagerie.CreateItem(0)
        With email
            .To = qui
            .Subject = "Alerte sur fin de contrat"
            .htmlbody = txt & .htmlbody
            .display ' à remplacer par .send si ok
        End With
        Set email = Nothing
    Next
End With

Set messagerie = Nothing

End Sub
Sub auto_open()
    alerter
End Sub

Function FeuilleExiste(sNomFeuille As String) As Boolean
    On Error GoTo Err_FeuilleExiste
    FeuilleExiste = False
    FeuilleExiste = Not ActiveWorkbook.Worksheets(sNomFeuille) Is Nothing
Err_FeuilleExiste:
End Function

Michel, nous tenions sincèrement à vous remercier pour votre aide, efficacité et réactivité !

Ce fichier va nous faciliter la vie

Katia et Jamie

Content que cela aide ... si à l'avenir il y avait un autre soucis, je suis là (et tout le forum si besoin)