Convertir le résultat d'une formule

Question

Une petite question comme ca, est-il possible de convertir (données/convertir) le résultat d'une formule? car j'ai essayé et ca convertie la formule. et ce bien sur en laissant les formules (c'est a dire sans rusé en copiant /collant les valeurs) Cordialement...

Invité · Answer

Maguetlolo, je verrais une solution par macro. Un exemple de quelles lignes avec les résultats désirés. A te relire Mytå...

Invité · Answer

Re le forum

Maguetlolo, ton code pour extraire (Je traite le séparateur point-virgule)

Sub Données_Convertir()
'
' Macro Données/Convertir
' Macro par Mytå pour Maguetlolo
' Forum Excel-Pratique le 07/02/2009
' Touche de raccourci du clavier: Ctrl+Maj+T
'
    Dim Tableau() As String
    Dim i As Integer
    Dim PlageSource As Range
    Dim Cellule As Range

'Permet de sélectionner une plage avec la souris (Méthode InputBox)
    Set PlageSource = Application.InputBox _
        ("Sélectionnez la ou les cellule(s) à traiter !", "Plage source", Type:=8)

'On boucle sur la plage source
For Each Cellule In PlageSource
    Tableau = Split(Cellule, ";")
    For i = 0 To UBound(Tableau)
        'Le résultat s'affiche à coté de la Cellule
        Cellule.Offset(0, i + 1) = Tableau(i)
    Next i
Next Cellule

    Set PlageSource = Nothing

End Sub

Tu lances la macro, tu sélectionnes la Plage de cellules à traiter.

Si cela te convient on peux ajouter le séparateur et vérifier si pas

des colonnes multiples de sélectionnées.

Mytå

Invité · Answer

Re le forum

Avec le test d'une colonne unique

Sub Données_Convertir()
'
' Macro Données/Convertir
' Macro Mytå pour Maguetlolo
' Forum Excel-Pratique le 07/02/2009
' Touche de raccourci du clavier: Ctrl+Maj+T
'
    Dim Tableau() As String
    Dim i As Integer
    Dim PlageSource As Range
    Dim Cellule As Range

'Permet de sélectionner une plage avec la souris (Méthode InputBox)
    Set PlageSource = Application.InputBox _
        ("Sélectionnez la ou les cellule(s) à traiter !", "Plage à Convertir", Type:=8)

'On vérifie le nombre de colonnes
  If PlageSource.Columns.Count > 1 Then
    MsgBox ("Vous ne pouvez sélectionner qu'une colonne")
    Exit Sub
  End If

'On boucle sur la Plage à Convertir
  For Each Cellule In PlageSource
    Tableau = Split(Cellule, ";") 'On peut ici modifier le séparateur
    For i = 0 To UBound(Tableau)
        'Le résultat s'affiche à coté de la Cellule
        Cellule.Offset(0, i + 1) = Tableau(i)
    Next i
  Next Cellule

    Set PlageSource = Nothing

End Sub

Mytå

thibo · Answer

Pour le plaisir, une solution formule : en E4 : =SI(ESTNUM(CHERCHE(" ";SUPPRESPACE(SUBSTITUE($D4;";";" "))));GAUCHE(SUPPRESPACE(SUBSTITUE($D4;";";" "));TROUVE(" ";SUPPRESPACE(SUBSTITUE($D4;";";" ")))-1);SUPPRESPACE(SUBSTITUE($D4;";";" "))) en F4 : =SI(ESTNUM(CHERCHE(" ";SUPPRESPACE(SUBSTITUE($D4;";";" "))));STXT(SUPPRESPACE(SUBSTITUE($D4;";";" "));TROUVE(" ";SUPPRESPACE(SUBSTITUE($D4;";";" ")))+1;99);"") à recopier vers le bas Suppose qu'il n'y a que deux couleurs. Mais gérable quand même avec plus de deux couleurs avec formule un peu plus ... costaud. Bon dimanche @+...

thibo · Answer

Re, ok, je te donne quand même le principe que j'ai utilisé pour que tu puisses essayer de l'adapter et l'utiliser dans une macro : J'ai remplacé les ; par des espaces Puis avec la fonction SUPPRESPACE, j'ai supprimé les espaces "inutiles", c'est-à-dire les espaces de début et fin de chaine ainsi que les espaces en doublon. On obtient ainsi une chaine dont le séparateur est l'espace. Je ne peux aller plus loin, car question VBA, je suis en dessous du niveau débutant. @+...

Invité · Answer

Re le forum

Maguetlolo, ta macro comme demandé

Sub Données_Convertir()
'
' Macro Données/Convertir sans vide ni espace
' Macro Mytå pour Maguetlolo
' Forum Excel-Pratique le 08/02/2009
'
    Dim Tableau() As String
    Dim i As Integer, j As Byte
    Dim Cellule As Range

'On boucle sur la Plage à Convertir
  For Each Cellule In Range("D4:D10")
    j = 1 'Remplacer par zéro pour écrire sur la formule
    Tableau = Split(Cellule, ";") 'On peut ici modifier le séparateur
    For i = 0 To UBound(Tableau)
      If Len(Trim(Tableau(i))) > 0 Then
        'Le résultat s'affiche si non vide
        Cellule.Offset(0, j) = Trim(Tableau(i))
        j = j + 1
      End If
    Next i
  Next Cellule

End Sub

Pour écrire sur la formule remplace j=1 par j=0

Mytå

Invité · Answer

Re le forum

Maguetlolo, tu n'oublies pas une petite formalité ...

Dès que votre problème est résolu, merci de le marquer en tant que [Résolu]
grâce à l'utilitaire se trouvant en bas de page, aperçu :

Mytå