ComboBox en cascade "spéciale" [Répondu]

Question

Bonjour,

Je fais appel à vous malgré les nombreux messages à ce sujet car je n'ai pas trouvé la réponse à mon problème...

J'ai créé un formulaire afin de remplir un tableau excel, je souhaite maintenant que ces données soient modifiables. Etant donné que le tableau devrait contenir environ 1000 lignes, je souhaite facilité la recherche des données avec des ComboBox en cascade. Mais les colonnes contenant les données des ComboBox ne se succèdent pas et je n'arrive pas à adapter un code à ma situation...

Il faudrait que:

    - La ComboBox1 reprenne les données de la colonne "F"
    - La ComboBox2 reprenne les données de la colonne "D"
    - La ComboBox3 reprenne les données de la colonne "B"
    - Lorsque les données de la ComboBox3 sont sélectionnées, le formulaire devrait se pré-remplir avec les données de la ligne correspond.

Certaines données sont confidentiels, j'ai donc modifié un peu le tableau et le formulaire, mais cela n'affectera pas les formules (il y a simplement plus de TextBox et de colonnes remplies dans le formulaire)

Je suis débutant en VBA il y a peut être des erreurs dans mon code ou des incohérences, mais tant que ça fonctionne je suis content

Merci d'avance pour votre aide

PS: si en plus vous pouvez mettre la TextBox "Date" en format date (jj/mm/aaaa) cela m'aiderais

25test-formulaire-v1.xlsm (166.77 Ko)

ThauThème · Answer

Bonjour K-Zimodo, bonjour le forum,

Le début du code, tu complèteras...

Option Compare Text
Private D As Worksheet
Private TV As Variant
Private DL As Long

Private Sub UserForm_Initialize()
Dim D1 As Object
Dim D2 As Object
Dim D3 As Object

Set D = Worksheets("données")
DL = D.Cells(Application.Rows.Count, "A").End(xlUp).Row
TV = D.Range("A1:G" & DL)
Set D1 = CreateObject("Scripting.Dictionary")
Set D2 = CreateObject("Scripting.Dictionary")
Set D3 = CreateObject("Scripting.Dictionary")
For I = 4 To DL
    D1(TV(I, 6)) = ""
    D2(TV(I, 4)) = ""
    D3(TV(I, 2)) = ""
Next I
Me.ComboBox1.List = D1.keys
Me.ComboBox2.List = D2.keys
Me.ComboBox3.List = D3.keys
End Sub

Private Sub ComboBox3_Change()
If Me.ComboBox1.Value = "" Or Me.ComboBox2.Value = "" Then Exit Sub
For I = 4 To DL
    If CStr(TV(I, 6)) = Me.ComboBox1.Value And CStr(TV(I, 4)) = Me.ComboBox2.Value And CStr(TV(I, 2)) = Me.ComboBox3.Value Then
        Me.TextBox2.Value = Me.ComboBox3.Value

        'ici tu complèteras les autres textboxes...

        Exit For
    End If
Next I
End Sub

ThauThème · Answer

Re,

J'avsis oublié de définir le numéro de ligne no_ligne. Mais toi, de ton coté, tu as rajouté des textboxes en pagaille qui n'existent même pas dans ta UserForm. Je n'y comprend rien !...

Le code complet avec les filtres et le numéro de ligne :

Private O As Worksheet
Private DL As Long
Private TV As Variant
Private no_ligne As Long

Private Sub UserForm_Initialize()
Dim D As Object
Dim I As Long

Set O = Worksheets("données")
DL = O.Cells(Application.Rows.Count, "A").End(xlUp).Row
TV = O.Range("A1:G" & DL)
Set D = CreateObject("Scripting.Dictionary")
For I = 4 To DL
    D(TV(I, 6)) = ""
Next I
Me.ComboBox1.List = D.keys
End Sub

Private Sub ComboBox1_Change()
Dim D As Object
Dim I As Long

Set D = CreateObject("Scripting.Dictionary")
For I = 4 To DL
    If CStr(TV(I, 6)) = Me.ComboBox1.Value Then D(TV(I, 4)) = ""
Next I
Me.ComboBox2.List = D.keys
End Sub

Private Sub ComboBox2_Change()
Dim D As Object
Dim I As Long

Set D = CreateObject("Scripting.Dictionary")
For I = 4 To DL
    If CStr(TV(I, 6)) = Me.ComboBox1.Value And CStr(TV(I, 4)) = Me.ComboBox2.Value Then D(TV(I, 2)) = ""
Next I
Me.ComboBox3.List = D.keys
End Sub

Private Sub ComboBox3_Change()
If Me.ComboBox1.Value = "" Or Me.ComboBox2.Value = "" Then Exit Sub
For I = 4 To DL
If CStr(TV(I, 6)) = Me.ComboBox1.Value And CStr(TV(I, 4)) = Me.ComboBox2.Value And CStr(TV(I, 2)) = Me.ComboBox3.Value Then
    no_ligne = I
    Me.TextBox2.Value = Me.ComboBox3.Value
    Me.TextBox3.Value = Cells(no_ligne, 3)
    Me.TextBox4.Value = Cells(no_ligne, 4)
    Me.TextBox5.Value = Cells(no_ligne, 5)
    Me.TextBox6.Value = Cells(no_ligne, 6)
    Me.TextBox7.Value = Cells(no_ligne, 7)
    Exit For
End If
Next I
End Sub

grisan29 · Answer

Bonsoir Thauthème, K-simodo et le forum Thauthème j'ai fait un essai de ton dernier code sur fichier fourni dans le 1er post et j'ai un biug a combobox1 au 1er TV comme tu peux le voir sur l’aperçu joint...