Utilisation de colonne envoyer par parametre

bonjour tout le monde,

j'ai fais beaucoup de recherche mais je ne trouve pas ce que je cherche

est ce qu'il y a quelqu’un qui pour m'aider

sub test()

Set col = Range("A2:A15")

Call Remplir_Combobox(UserForm9, UserForm9.ComboBox2, col)

end sub

Sub Remplir_Combobox(ByRef nomuserforme As UserForm, nomcombobox As ComboBox, colonne As Range)

dim tableau() as integer

ici je veux remplir le tableau par la colonne envoyer je veux que le remplissage ce fait cellule par cellule cad avec la boucle for car entre temps je veux insérer des informations dans le tableau

end sub

merci d'avance pour votre aide

Bonjour,

Soit plus précis car je n'ai rien compris à ce que tu veux !

Bonsoir,

Ça me fait planer moi aussi .

En partant comme ça je suis curieux de voir où tu vas arriver.

Salut tout le monde,

à mon idée, il veut charger une Combo avec les valeurs d'une colonne dont l'adresse serait envoyée à une procédure en argument.

Là où j'attends de voir, c'est qu'il a l'air de vouloir interrompre le chargement de la Combo pour pouvoir insérer des valeurs (dans la Combo, j'imagine) avant de reprendre le chargement...

Va être drôle, ça...

A+

Bonjour,

Donc, en partant de ce qu'en a compris curulis57 (bravo à lui !) une piste :

Private Sub CommandButton1_Click()

    Dim Tablo()
    Dim I As Integer

    Tablo = Remplir(ActiveSheet.Range("A1:A15"))

    For I = 1 To UBound(Tablo)

        ComboBox2.AddItem Tablo(I)

    Next I

End Sub

Function Remplir(Plage As Range) As Variant()

    Dim Tbl()
    Dim cel As Range
    Dim I As Integer
    Dim Valeur

    For Each cel In Plage

        I = I + 1
        ReDim Preserve Tbl(1 To I)
        Tbl(I) = cel.Value

    Next cel

    Valeur = InputBox("Quelles valeurs voulez-vous intégrer au tableau avant chargement de la ComboBox ?" & _
                      vbCrLf & _
                      "Séparer les valeurs pas un point-virgule (;) !", "Ajout de valeurs")

    For I = 0 To UBound(Split(Valeur, ";"))

        ReDim Preserve Tbl(1 To UBound(Tbl) + 1)
        Tbl(UBound(Tbl)) = Split(Valeur, ";")(I)

    Next I

    Tri Tbl

    Remplir = Tbl

End Function

Sub Tri(Tbl())

    Dim Tempo
    Dim I As Integer
    Dim J As Integer

    For I = 1 To UBound(Tbl) - 1

        For J = I + 1 To UBound(Tbl)

            'décroissant "<", croissant ">"
            If Tbl(I) > Tbl(J) Then

                Tempo = Tbl(J)
                Tbl(J) = Tbl(I)
                Tbl(I) = Tempo

            End If

        Next J

    Next I

End Sub

Fichtre !

Bonne journée à vous.

En lustrant un peu ma boule de cristal (je n'arrivais même plus à lire dans les pensées de sotuma, c'est fou ça non ?) et avec l'intuition légendaire de curulis57, j'ai pondu ce code avec mes petits neurones