VBA : Copier-coller des fichiers .jpg

Bonsoir,

Pour l’instant je ne suis pas très avancé avec mon projet

J’ai deux images au format .jpg, listées dans la colonne A, au bout du chemin indiqué en G1.

En cliquant sur mon bouton, je voudrais pouvoir choisir un nouveau dossier (ça c’est bon, ma macro en place permet d’affecter à la variable ‘’Chemin’’ le nouveau dossier choisi) et de placer des copies de ces images dans ce nouveau dossier en leur appliquant de nouveaux noms. Afin de simplifier pour l’instant, disons qu’il faudrait simplement que les images copiées s’appellent ‘’Copie Image 1’’ et ‘’Copie Image 2’’.

Pouvez-vous m’aider ?

Chaleureusement.

Bonjour,

A tester :

Declare Function CopyFile _
        Lib "kernel32" _
        Alias "CopyFileA" ( _
        ByVal lpExistingFileName As String, _
        ByVal lpNewFileName As String, _
        ByVal bFailIfExists As Long) As Long

Sub Transfert()

    Dim Fe As Worksheet
    Dim Plage As Range
    Dim Cel As Range
    Dim DossierSource As String
    Dim DossierCible As String
    Dim Ecraser As Long

    With Application.FileDialog(msoFileDialogFolderPicker)

        If .Show = -1 Then DossierCible = .SelectedItems(1) & "\" Else Exit Sub

    End With

    Set Fe = Worksheets("Feuil1")

    With Fe: Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp)): End With

    DossierSource = Fe.Range("G1") & "\"

    For Each Cel In Plage

        Ecraser = True

        CopyFile DossierSource & Cel.Value, DossierCible & "Copie de " & Cel.Value, Abs(CLng(Not Ecraser))

    Next Cel

End Sub

Salut These,

Merci infiniment pour ta réponse ; ça correspond exactement à mon besoin

Il ne me reste plus qu'à appliquer ta solution au besoin du membre ex75 que je tente d'aider.

Très bonne continuation.

Bonne continuation à toi aussi et bon dimanche !