Boucle pour plusieurs onglet

J'ai un fichier qui contient plusieurs onglets de saisie

Dans les colonnes "L" et "M" des chiffres devraient êtres saisis, si ce n'est pas le cas je voudrais faire une boucle passant toutes les cellules de ces deux colonnes de chaque onglet du classeur hormis deux nommés "pointage-étude" et "Menu" afin d'inscrire un "0" zéro dans les cases vides.

Je place en pièces jointes le fichier

attention les codes sont contenu dans les boutons

D'avance je vous remercie pour votre aide et votre disponibilité

bonsoir ealo-33

essayé ce code

Sub iCopy()

Application.ScreenUpdating = False

       Dim sh As Worksheet, Cel As Range, Last As Long
 For Each sh In Sheets(Array("DELOG_1", "DELOG_2", "DELOG_3", "DELOG_4", "DELOG_5", "DELOG_6"))
                Last = sh.Cells(Rows.Count, 1).End(xlUp).Row
                For Each Cel In sh.Range("L2:M" & Last)
               If IsEmpty(Cel) = True Then Cel.Value = 0
        Next
 Next

Application.ScreenUpdating = True

End Sub

Bonjour le forum

Bonjour belkacem64, merci pour ta disponibilité et pour ton aide

Ok je prends , j'ai juste modifié l'es "Array", en définissant les onglets que je voulais extraire de la boucle

sub Copy_0()

Dim sh As Worksheet

Application.ScreenUpdating = False

    For Each sh In Worksheets
         If sh.Name <> "DELOG" And sh.Name <> "Menu" And sh.Name <> "pointage-etude" Then
            Last = sh.Cells(Rows.Count, 1).End(xlUp).Row
            For Each Cel In sh.Range("K2:L" & Last)
               If IsEmpty(Cel) = True Then Cel.Value = 0
            Next
         End If

    Next sh

Application.DisplayAlerts = False

End Sub

merci beaucoup pour ton aide

Bonjour,

Une alternative à étudier.

Cdlt.

Sub Copy_1()
Dim ws As Worksheet
Dim rng As Range

    Application.ScreenUpdating = False

    For Each ws In ActiveWorkbook.Worksheets
        Select Case ws.Name
            Case "DELOG", "Menu", "pointage-etude"
                '
            Case Else
                Set rng = ws.Cells(1).CurrentRegion.Offset(, 10). _
                          Resize(, 2).SpecialCells(xlCellTypeBlanks)
                rng.Value = 0
        End Select
    Next ws

    Set rng = Nothing

End Sub