Créer un bouton cliquable pour exporter en PDF

Le 27/03/2014 à 16:37

rebonjour! je voudrais savoir comment peut-on créer un bouton cliquable pour exporter en PDF sur ma feuille excel ?

merci encore!

JL

1'133plan-d-action-it01-forum.xlsx (15.51 Ko)
Le 28/03/2014 à 10:20

Bonjour,

Une proposition.

Voir fichier (répertoire et nom fichier à déterminer).

1'642plan-d-action-it01-forum.xlsm (27.77 Ko)
Option Explicit
Private Sub cmdCreerPDF_Click()
Dim Répertoire As String, _
    Fichier As String, _
    feuille As Variant, _
    Nom As Name

    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With

    'Si la feuille est vide on stoppe tout.
    If IsEmpty(ActiveSheet.UsedRange) Then Exit Sub

    'Dossier de destination des fichiers PDF créés
    Répertoire = "D:\"
    'On crée un nouveau document en copiant la feuille active
    ActiveSheet.Copy

    With ActiveSheet
        'On donne au fichier PDF le nom de la feuille active
        Fichier = .Name & ".pdf"
        'On crée le nouveau document au format PDF
        .ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=Répertoire & Fichier, _
            Quality:=xlQualityMinimum, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=False
    End With

    'On ferme le document que l'on vient de crée
    ActiveWorkbook.Close False
    'On passe à la feuille suivante

    Application.DisplayAlerts = True

End Sub
Le 28/03/2014 à 10:43

Re,

Une petite amélioration.

On vérifie que le fichier n'existe pas.

2'252plan-d-action-it01-forum-v2.xlsm (27.85 Ko)
Option Explicit
Private Sub cmdCreerPDF_Click()
Dim Répertoire As String, _
    Fichier As String, _
    feuille As Variant, _
    Nom As Name

    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With

    'Si la feuille est vide on stoppe tout.
    If IsEmpty(ActiveSheet.UsedRange) Then Exit Sub

    'Dossier de destination des fichiers PDF créés
    Répertoire = "D:\"

    With ActiveSheet
        'On donne au fichier PDF le nom de la feuille active
        Fichier = .Name & ".pdf"
        'On vérifie que le fichier n'existe pas.
        If ExistenceFichier(Répertoire & Fichier) Then
            MsgBox " Le fichier existe déjà."
            Exit Sub
        End If
        'On crée un nouveau document en copiant la feuille active
        .Copy
        'On crée le nouveau document au format PDF
        .ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=Répertoire & Fichier, _
            Quality:=xlQualityMinimum, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=False
    End With

    'On ferme le document que l'on vient de crée
    ActiveWorkbook.Close False
    'On passe à la feuille suivante

    Application.DisplayAlerts = True

End Sub
Option Explicit
Function ExistenceFichier(sFichier As String) As Boolean
    ExistenceFichier = Dir(sFichier) <> ""
End Function
Le 30/03/2014 à 16:11

Woooa trop puissant !!!

Le 19/11/2014 à 15:56

bonjour,

vous pouvez poster le fichier corrigé, j'ai un probleme quand je fais le copier/coller

merci

Le 19/11/2014 à 16:25

Bonjour,

Le fichier est joint dans mon dernier message.

Cdlt.

Le 19/11/2014 à 21:42

bonsoir,

Il m'affiche l'erreur 52 : nom ou numéro de fichier incorrect!

Merci par avance

Le 20/11/2014 à 07:44

Bonjour,

Vérifie le nom de la feuille de calcul.

Sinon envoie to fichier.

Cdlt.

Le 20/11/2014 à 11:35

Bonjour,

j’utilise le dernier fichier posté

Merci beaucoup

Le 18/10/2016 à 23:32

Bonsoir Messiers ou Mesdames,

Petite problématique dans mon cas une partie de la macro s'affiche en jaune (J'ai voulu que le PDF créé porte le nom de deux variable du fichier exel)

Auriez-vous une solution? merci d'avance

Private Sub Validation_Click()
Dim Répertoire As String, _
    Fichier As String, _
    feuille As Variant, _
    Nom As Name

    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With

    'Si la feuille est vide on stoppe tout.
   If IsEmpty(ActiveSheet.UsedRange) Then Exit Sub

    'Dossier de destination des fichiers PDF créés
   Répertoire = "C:\Users\Desktop"

    With ActiveSheet
        'On donne au fichier PDF le nom de la feuille active
      Fichier = "Main Courante" & Range("F2").Value.Range("D4").Value & ".pdf"
        'On crée le nouveau document au format PDF
       .ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=Fichier, _
            Quality:=xlQualityMinimum, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=True
    End With

    'On ferme le document que l'on vient de crée
   ActiveWorkbook.Close False
    'On passe à la feuille suivante

    Application.DisplayAlerts = True

End Sub
Le 19/10/2016 à 17:59

Alors Gillow, as tu une solution à ton probleme ? J'essaye de mon coté sans trouver de solution. Mon probleme est presque similaire puisque mon fichier doit s'appeller "PROJET" ainsi que le contenu de la cellule B8 (nom du client). Je trouve pas, donc j'attends une âme charitable

Le 19/10/2016 à 21:39

Nom pas encore je replanche dessus demain soir si j'ai une réponse, je la posterai promis.

Le 20/10/2016 à 01:35

Bonjour,

Remplace :

Fichier = "Main Courante" & Range("F2").Value.Range("D4").Value & ".pdf"

par :

Fichier = "Main Courante" & Range("F2").Value & Range("D4").Value & ".pdf"

Cdlt.

Le 21/10/2016 à 18:38

Merci beaucoup je teste dès que je rentre de congés

Le 03/11/2016 à 21:13

Bonsoir enfin rentrée de congés, donc j'ai essayé de remplacer la ligne de code et l'erreur s'est déplacée, je me demande si cela viens bien d'une faute de syntaxe.

Private Sub Validation_Click()
Dim Répertoire As String, _
    Fichier As String, _
    feuille As Variant, _
    Nom As Name

    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With

    'Si la feuille est vide on stoppe tout.
  If IsEmpty(ActiveSheet.UsedRange) Then Exit Sub

    'Dossier de destination des fichiers PDF créés
  Répertoire = "C:\Users\Desktop"

    With ActiveSheet
        'On donne au fichier PDF le nom de la feuille active
Fichier = "Main Courante" & Range("F2").Value & Range("D4").Value & ".pdf"
        'On crée le nouveau document au format PDF
      .ExportAsFixedFormat _
Type:=xlTypePDF, _
            Filename:=Fichier, _
            Quality:=xlQualityMinimum, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=True
    End With

    'On ferme le document que l'on vient de crée
  ActiveWorkbook.Close False
    'On passe à la feuille suivante

    Application.DisplayAlerts = True

End Sub
Le 03/11/2016 à 21:57

bonsoir a vous

je ne sais pas si j'ai la réponse mais il y a quelque chose qui me gêne a cette ligne sans l'avoir essayer

Fichier = "Main Courante" & Range("F2").Value & Range("D4").Value & ".pdf"

"main courante" c'est quoi et il manque les . devant les range

Le 03/11/2016 à 22:14
137main-courante.xlsm (59.33 Ko)
grisan29 a écrit :

bonsoir a vous

je ne sais pas si j'ai la réponse mais il y a quelque chose qui me gêne a cette ligne sans l'avoir essayer

Fichier = "Main Courante" & Range("F2").Value & Range("D4").Value & ".pdf"

"main courante" c'est quoi et il manque les . devant les range

"main courante" c'est la partie du nom du fichier qui ne change jamais

exemple du nom: Main Courante "variable F2""variable F4".pdf

ensuite dans les messages précédents on m'a fait supprimer les points, je cherche de mon côté si tu peux me filer un coups de main ce serait sympa

Je vous ai mis le fichier pour vous aidez

Le 18/11/2016 à 23:06

bonsoir

est ce que tu as trouvé depuis car en bas du post il y a des réponses a des questions du même genre voir ceci par exemple

https://forum.excel-pratique.com/excel/creer-sous-dossier-pour-exportation-pdf-t53944.html

Rechercher des sujets similaires à "creer bouton cliquable exporter pdf"