Bouton supprimer rendez vous

Bonjour,

Je suis en train de faire un planning et j'ai un problème avec le bouton supprimer de mon fichier.

Enfaite je voudrais qu'il supprime le rendez-vous que je lui indique et qui sont tous stockés dans ma feuille "prise". Le problème est que pour la rechercheV que j'ai faite sur ce bouton il prend les données qui sont sur le feuille "semaine" et non la feuille "prise". Je ne comprends pas pourquoi. Pouvez vous m'aider ?

Voici mon code :

Private Sub CB_Rdv_Change()

With Worksheets("prise")

ligne2 = [A2].Offset(CB_Rdv.ListIndex, 0).Row

Me.TB_HD.Text = Cells(ligne2, 2)

Me.TB_HF.Text = Cells(ligne2, 3)

Me.TB_Intervenant.Text = Cells(ligne2, 4)

Me.TB_Nom.Text = Cells(ligne2, 7)

Me.TB_Prenom.Text = Cells(ligne2, 8)

Range("A2").Offset(CB_Rdv.ListIndex, 0).Select

End With

End Sub

Private Sub CB_supprimer_Click()

Var = Sheets("prise").Range("A:A").End(xlDown).Row + 1

r = MsgBox("Voulez-vous supprimer ce rendez-vous ?", vbYesNo, "Demande de suppression")

Selection.EntireRow.Delete

UserForm_Initialize

End Sub

Private Sub UserForm_Initialize()

With Worksheets("prise")

lig = Range("A" & Rows.Count).End(xlUp).Row

CB_Rdv.List = .Range("A2:A1000").Value

CB_Rdv.ListIndex = 0

End With

End Sub

J'ai également joins mon fichier -->

Merci.

Bonjour,

essaye de changer cette ligne :

Selection.EntireRow.Delete

Par :

var.EntireRow.Delete

Bonjour le fil, bonjour le forum,

Ton code revu et modifié :

Private Sub UserForm_Initialize()
Dim lig As Integer
With Worksheets("prise")
    lig = .Range("A" & Rows.Count).End(xlUp).Row
    CB_Rdv.List = .Range("A2:A" & lig).Value
End With
End Sub

Private Sub CB_Rdv_Change()
Dim ligne2 As Integer
With Worksheets("prise")
    ligne2 = CB_Rdv.ListIndex + 2
    Me.TB_HD.Text = Format(.Cells(ligne2, 2), "hh:mm")
    Me.TB_HF.Text = Format(.Cells(ligne2, 3), "hh:mm")
    Me.TB_Intervenant.Text = .Cells(ligne2, 4)
    Me.TB_Nom.Text = .Cells(ligne2, 7)
    Me.TB_Prenom.Text = .Cells(ligne2, 8)
    .Cells(ligne2, 1).Select
End With
End Sub

Private Sub CB_supprimer_Click()
Var = Sheets("prise").Range("A:A").End(xlDown).Row + 1
If MsgBox("Voulez-vous supprimer ce rendez-vous ?", vbYesNo, "Demande de suppression") = vbNo Then Exit Sub
Selection.EntireRow.Delete
Unload Me
UserForm1.Show
End Sub

Bonjour,

Merci pour ton code; mais je ne peux toujours pas supprimer de rendez vous quand je suis sur la feuille "semaine".

Bonjour le fil, bonjour le forum,

On est bien d'accord, le code ne supprime que dans l'onglet prise, pas dans l'onglet semaine ?!

Dans ce cas le code ci-dessous devrait fonctionner :

Private Ligne2 As Integer
Private P As Worksheet

Private Sub UserForm_Initialize()
Dim lig As Integer

Set P = Sheets("prise")
lig = P.Range("A" & Rows.Count).End(xlUp).Row
CB_Rdv.List = P.Range("A2:A" & lig).Value
End Sub

Private Sub CB_Rdv_Change()
Ligne2 = CB_Rdv.ListIndex + 2
Me.TB_HD.Text = Format(P.Cells(Ligne2, 2), "hh:mm")
Me.TB_HF.Text = Format(P.Cells(Ligne2, 3), "hh:mm")
Me.TB_Intervenant.Text = P.Cells(Ligne2, 4)
Me.TB_Nom.Text = P.Cells(Ligne2, 7)
Me.TB_Prenom.Text = P.Cells(Ligne2, 8)
End Sub

Private Sub CB_supprimer_Click()
If MsgBox("Voulez-vous supprimer ce rendez-vous ?", vbYesNo, "Demande de suppression") = vbNo Then Exit Sub
P.Rows(Ligne2).Delete
Unload Me
UserForm1.Show
End Sub

Fait bien attention à laisser les deux premières ligne au début du code...