Sauvegarder en PDF les feuilles sélectionnées dans ListBox

Bonjour, j'aimerais pouvoir sélectionner une ou plusieurs feuilles dans une listbox puis pouvoir l'enregistrer en UN SEUL PDF.

Voici mon alimentation de Userform (ca génère les feuilles du classeur)

Private Sub UserForm_Initialize()

    Dim feuille As Worksheet
    For Each feuille In ActiveWorkbook.Worksheets

        ListBox1.AddItem feuille.Name

    Next

End Sub

Maitenant je voudrais pouvoir sauvegarder avec un code du genre:

Sub SaveAsPDFCalendrier()
Call Répertoire
    Dim fName As Variant
    Dim Nom$
    Dim Year$
    Nom = Range("L5").Value

ThisWorkbook.Sheets(Array(Me.ListBox1.Selected)).Select

    fName = Application.GetSaveAsFilename( _
        InitialFileName:="c:\chemin\Calendrier\PDF\Planning-" & Nom & ".pdf", _
        FileFilter:="PDF files, *.pdf", _
        Title:="Sauvegarder Planning en PDF")
    If fName <> False Then
        ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=fName _
            , Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _
            :=False, OpenAfterPublish:=True
End If
End Sub

Bref ca ne fonctionne pas jusqu'à maintenant ... HELP

J'ai aussi essayé

Worksheets(ListBox1.Value).Select

Bonjour

Ce que j'ai trouvé

Sub SaveAsPDFCalendrier()
Call Répertoire
Dim fName As Variant
Dim Nom$
Dim Year$

Dim Ws As Worksheet
Dim Tablo(), I As Integer, Indice As Integer

  Set Ws = ActiveSheet
  Nom = Range("L5").Value
  With Me.ListBox1
    For I = 0 To .ListCount - 1
      If .Selected(I) = True Then
        ReDim Preserve Tablo(Indice)
        Tablo(Indice) = .List(I)
        Indice = Indice + 1
      End If
    Next I
  End With

  fName = Application.GetSaveAsFilename( _
          InitialFileName:="c:\chemin\Calendrier\PDF\Planning-" & Nom & ".pdf", _
          FileFilter:="PDF files, *.pdf", _
          Title:="Sauvegarder Planning en PDF")
  If fName <> False Then
    Sheets(Tablo).Select
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=fName, _
                                    Quality:=xlQualityStandard, IncludeDocProperties:=True, _
                                    IgnorePrintAreas:=False, OpenAfterPublish:=True
    Ws.Select
  End If

End Sub

Fidèle à tes habitudes ... ca fonctionne!

merci bcp Banzai64!!