VBA_Masquer entête, quadrillage, barre de formule

Bonjour à tous,

Je cherche un code VBA qui me permet de masquer l'entête, quadrillage et barre de formule dans une feuille spécifique (feuille 2 )

Merci

Bonsoir,

Fais toutes ces manip avec l'enregistreur de macro activé...

Cordialement, Daniel

Bonsoir,

Attention, l'option d'affichage de la barre de formule est effective est liée à l'application.

Bonjour et bonne année,

Ci-dessous 2 procédures événementielles à placer dans le module ThisWorkbook du classeur.

Cdlt.

Option Explicit

Private Sub Workbook_SheetActivate(ByVal Sh As Object)

    If Sh.Name = "Feuil2" Then
        With Application
            .DisplayFormulaBar = False
            .ScreenUpdating = False
        End With
        With ActiveWindow
            .DisplayGridlines = False
            .DisplayHeadings = False
        End With
    End If

End Sub

Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)

    If Sh.Name = "Feuil2" And Application.DisplayFormulaBar = False Then
        With Application
            .DisplayFormulaBar = True
            .ScreenUpdating = False
        End With
    End If

End Sub

Merci beaucoup Jean Eric

bien fait

Est ce que c'est possible de masquer aussi le ruban avec quadrillage, entête et barre de formule, tous ça uniquement dans la feuil2?

Merci d'avance

Re,

Essaie ceci :

Option Explicit
'----------------------------------------------------------------------------
Private Sub Workbook_SheetActivate(ByVal Sh As Object)

    If Sh.Name = "Feuil2" Then
        With Application
            .ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",False)"
            .DisplayFormulaBar = False
            .ScreenUpdating = False
        End With
        With ActiveWindow
            .DisplayGridlines = False
            .DisplayHeadings = False
        End With
    End If

End Sub
'----------------------------------------------------------------------------
Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)

    If Sh.Name = "Feuil2" Then
        With Application
            .ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",True)"
            .DisplayFormulaBar = True
            .ScreenUpdating = False
        End With
    End If

End Sub

Merci Beaucoup Jean Eric.

et comment faire si j'ai certains feuilles à appliquer le code vba par exemple Feuille 2, feuille 4 et feuille 6?

Re,

A tester.

Cdlt.

Option Explicit
'----------------------------------------------------------------------------
Private Sub Workbook_SheetActivate(ByVal Sh As Object)

    Select Case Sh.Name
        Case "Feuil2", "Feuil4", "Feuil6"
            With Application
                .ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",False)"
                .DisplayFormulaBar = False
                .ScreenUpdating = False
            End With
            With ActiveWindow
                .DisplayGridlines = False
                .DisplayHeadings = False
            End With
        Case Else
            '
    End Select

End Sub
'----------------------------------------------------------------------------
Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)

    Select Case Sh.Name
        Case "Feuil2", "Feuil4", "Feuil6"
            With Application
                .ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",True)"
                .DisplayFormulaBar = True
                .ScreenUpdating = False
            End With
        Case Else
            '
    End Select

End Sub

Merci bien JEAN ERIC