Fonction vlookup dans TCD

Bonjour le forum

Voici un fichier que j'extraie d'un TCD

Avec la macro de la Feuille 2, je voudrais renseigner les taux

correspondant aux codes de la feuille 1 avec la fonction Vlookup

Seulement il y a tjrs ces #N/A qui viennent et dont j'ai du mal

à m'en débarrasser.

Ou est le problème ? d'autant que toutes les valeurs de la feuille2

se trouvent sur la feuille 1 qui est la base

Merci par avance

Bonjour

Comme tu as 2007 essayes cette macro

Attention j'ai placé les résultats en colonne E

Sub Bouton1_Clic()
Dim wk1 As Worksheet, wk2 As Worksheet
Dim RngCells As Range, Target As Range, c As Range, cel As Range

  Derlig = Worksheets("Feuil2").Range("A" & Rows.Count).End(xlUp).Row
  Derlig1 = Worksheets("Feuil1").Range("A" & Rows.Count).End(xlUp).Row

  Set wk1 = Sheets("Feuil2")
  Set wk2 = Sheets("Feuil1")

  Set RngCells = wk1.Range(wk1.Cells(3, "A"), wk1.Cells(Derlig1, "D"))
  Set Target = wk2.Range(wk2.Cells(3, "A"), wk2.Cells(Derlig, "A"))

  With Target.Offset(, 4)
    .Formula = "=IFERROR(VLOOKUP(" & Target.Address & "," & RngCells.Address(external:=True) & ",3,0),"""")"
    .Value = .Value
  End With
End Sub

Bonjour Banzai64

Merci de t'être intéressé à mon projet.

Une partie du problème est effectivement réglée c'est à dire qu'il n y a plus ces "maudits "#N/A"

A la place il y a du blanc.

Mais la recherche s'est arrêté au 47121047

Alors qu'il fallait trouver pour le 47121048......5

47121051...... 2

47121056 .....1

Ces trois valeurs n'ont pas reçu leur correspondant respectifs

Bonjour

Il y a un mélange dans les variables

Je t'ai remis cela dans l'ordre

Sub Bouton1_Clic2()
Dim wk1 As Worksheet, wk2 As Worksheet
Dim RngCells As Range, Target As Range, DerLig1 As Long, DerLig2 As Long

  DerLig1 = Worksheets("Feuil1").Range("A" & Rows.Count).End(xlUp).Row
  DerLig2 = Worksheets("Feuil2").Range("A" & Rows.Count).End(xlUp).Row

  Set wk1 = Sheets("Feuil1")
  Set wk2 = Sheets("Feuil2")

  Set RngCells = wk2.Range(wk2.Cells(3, "A"), wk2.Cells(DerLig2, "D"))
  Set Target = wk1.Range(wk1.Cells(3, "A"), wk1.Cells(DerLig1, "A"))

  With Target.Offset(, 4)
    .Formula = "=IFERROR(VLOOKUP(" & Target.Address & "," & RngCells.Address(external:=True) & ",3,0),"""")"
    .Value = .Value
  End With
End Sub

Re Banzai64

GENIAL

Pile poil.

Merci à toi et au forum

Bon Week end