Boucle onglet

bonjour,

Dim l As Range

Dim m As Range

Set l = Sheets("aaaa")Range("N1:" & Sheets("aaaa").Cells(Rows.Count, 1).End(xlUp).Address)

Set m = Sheets("Feuil1").Range("A1:" & Sheets("Feuil1").Cells(Rows.Count, 1).End(xlUp).Address)

For Each cell In l

If Application.CountIf(m, cell.Value) > 0 Then

cell.Interior.ColorIndex = 26

End If

serait il possible de faire une boucle sur toutes les feuilles du classeur avec cette macro

la feuille 1 reste fixe , il faudrait remplacer Sheets("aaaa") par une déclaration

et si possible exclure de la boucle certaine feuil (exemple sheets "bbb")

cela fait 1 heure que je suis dessus et cela n'avance pas

une idée?

cordialement

Bonjour,

A tester (j'ai pas testé mais ça devrait aller) :

Sub Test()

    Dim Fe As Worksheet
    Dim Plage_A As Range
    Dim Plage_N As Range
    Dim Cel As Range

    'défini la plage en colonne A de feuille "Feuil1"
    With Worksheets("Feuil1")

        Set Plage_A = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))

    End With

    For Each Fe In Worksheets

        If Fe.Name <> "bbb" Then

            'défini la plage en colonne N de la feuille en cours
            With Fe

                Set Plage_N = .Range(.Cells(1, 14), .Cells(.Rows.Count, 14).End(xlUp))

            End With

            'boucle sur la plage
            For Each Cel In Plage_N

                If Application.CountIf(Plage_A, Cel.Value) > 0 Then Cel.Interior.ColorIndex = 26

            Next Cel

        End If

    Next Fe

End Sub

Hervé.

parfait , merci Hervé