Vérification de fichiers

Bonjour,

J'aurai une autre question dans ce code je vérifie si un des fichiers n'existent pas call la routine Retour_acceuil

cela fonctionne à peu prés je voudrais que si un fichier n'existe pas je retourne a la feuille "Import"

Sub verification_fichier()
'**********************************
'EMPECHE LE DÉFFILEMENT INTEMPESTIF
'**********************************
Application.ScreenUpdating = False

If Dir("C:\SYSTÈME DE GESTION \Besoin1.xls") = "" Then
MsgBox "le fichier *Besoin1.xls* n'existe pas ou vérifier le nom du fichier"
Else
If Dir("C:\SYSTÈME DE GESTION \Besoin2.xls") = "" Then
MsgBox "le fichier *Besoin2.xls* n'existe pas ou vérifier le nom du fichier"
Else
If Dir("C:\SYSTÈME DE GESTION \Besoin3.xls") = "" Then
MsgBox "le fichier *Besoin3.xls* n'existe pas ou vérifier le nom du fichier"

On Error Resume Next
'*****************************************************************
'SI LE FICHIER N'EST PAS CORRECTE CALL LA ROUTINE "Retour_acceuil"
'*****************************************************************
   Call Retour_acceuil 'dans le module "Verif_Fichier"
   Else
    '********************************************************************************************************
    'CALL LA ROUTINE "ajout ajout2 ajout3" QUI CE TROUVE DANS MODULE "PRINCIPALE_1 PRINCIPALE_2 PRINCIPALE_3"
    '********************************************************************************************************
  Call ajout
  Call ajout2
  Call ajout3
End If
End If
End If

End Sub

Sub Retour_acceuil()
'ACTIVE LA FEUILLE "IMPORT"
    Sheets("Import").Select
End Sub

Merci d'avance pour vos réponses

cordialement

Re,

Tu places ton instruction Sheets("Import").Select juste avant la fin de la première macro.

Cordialement.

bonjour,

j'ai essayé .Dans le code si dessous il y a appel de la routine "verification_fichier" qui ce trouve dans mon méssage plus haut qui ce déroule bien mais si un fichier n'est pas trouver il retourne a la page import comme prévu mais le code contininu et arrive a cette ligne Sheets("Achats_Jours").Select qui n'est pas créer puisque l'un des fichiers n'a pas été trouver et me provoque une erreur il faudrait que la routine "verification_fichier" s'arrête et me ramène a la page import

Private Sub CommandButton1_Click() 'BOUTON OK
If passe.Text <> "xxxxxxx" Then 'ICI MOT DE PASSE
MsgBox ("Mot de passe incorrect")
passe.SetFocus
'INITIALISE TEXTBOX EFFACE CONTENU
passe.Text = ""
Else
Unload Me 'SI BON CALL "verification_fichier" QUI CE TROUVE DANS MODULE "Verif_Fichier"

'**************************************************************
'AJOUTE UN MESSAGE DANS LA BARRE DU BAS Traitement en cours ...
'**************************************************************
Application.StatusBar = "Traitement en cours ..."

'CALL LA ROUTINE " verification_fichier" QUI CE TROUVE DANS LE MODULE "Verif_Fichier"
Call verification_fichier

'*************************************
'SELECTION DE LA FEUILLE "ACHAT_JOURS"
'*************************************
Sheets("Achats_Jours").Select

'***************************************************************
'ENLEVE LE  MESSAGE DANS LA BARRE DU BAS Traitement en cours ...
'***************************************************************
Application.StatusBar = False
End If
End Sub

Private Sub CommandButton2_Click() 'BOUTON ANNULER
'****************************
'ENLÉVE USERFORM MOT DE PASSE
'****************************
Unload Me
End Sub

Merci d'avance pour vos réponses

cordialement

Bonjour,

Je verrais plutôt ça, comme cela..

Private Sub CommandButton1_Click() 'BOUTON OK
    If passe.Text <> "xxxxxxx" Then 'ICI MOT DE PASSE
        MsgBox ("Mot de passe incorrect")
        'INITIALISE TEXTBOX EFFACE CONTENU
        passe.Text = ""
        passe.SetFocus
    Else
        Unload Me 'SI BON CALL "verification_fichier" QUI CE TROUVE DANS MODULE "Verif_Fichier"
'verification_fichier" QUI CE TROUVE DANS LE MODULE "Verif_Fichier"
        If Not Verification_Fichier Then
            Sheets("Import").Select
            Exit Sub
        End If
    End If
    '**********************************
    'EMPECHE LE DÉFFILEMENT INTEMPESTIF  ___ Empèche le raffraichissement ded feuilles
    '**********************************
    Application.ScreenUpdating = False

    '**************************************************************
    'AJOUTE UN MESSAGE DANS LA BARRE DU BAS Traitement en cours ...
    '**************************************************************
    Application.StatusBar = "Traitement en cours ..."
    '.... suite du code
End Sub

Function Verification_Fichier() As Boolean
    If Dir("C:\SYSTÈME DE GESTION \Besoin1.xls") = "" Then
        MsgBox "le fichier *Besoin1.xls* n'existe pas ou vérifier le nom du fichier"
        Exit Function
    ElseIf Dir("C:\SYSTÈME DE GESTION \Besoin2.xls") = "" Then
        MsgBox "le fichier *Besoin2.xls* n'existe pas ou vérifier le nom du fichier"
        Exit Function
    ElseIf Dir("C:\SYSTÈME DE GESTION \Besoin3.xls") = "" Then
        MsgBox "le fichier *Besoin3.xls* n'existe pas ou vérifier le nom du fichier"
        Exit Function
    End If
    Verification_Fichier = True
End Function

A+

Bonjour,

Merci beaucoup pour ta réponse et le code fonctionne parfaitement

merci aussi à toutes les autres personnes qui m'ont aidées

Cordialement