Compléter une macro

Bonsoir,

Dans un fichier excel où j'ai deux feuilles : une qui contient un tableau récapitulatif de dossiers "contentieux" avec un total des enjeux, des provisions et du nombre de dossiers (synthèse de bases de données autres), la première qui comprend une macro "Dates de modifications" avec le nom de la personne qui s'affiche à chaque fermeture du dossier ou plutôt sauvegarde. Je souhaiterais donc savoir s'il est possible de compléter cette macro qui préciserait également où s'est effectuée la modification, dans quelle cellule du tableau de la feuille 2.

Je joins le fichier, dont j'ai modifié certains éléments.

Merci de votre aide et/ou explications.

VALOU

Bonjour

Dans le module de la feuille "AMCF 2012" copies cette macro

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Ligne As Long

  With Sheets("DATES MODIFS")
    Ligne = .Range("A" & Rows.Count).End(xlUp).Row + 1
    .Range("A" & Ligne) = Application.UserName
    .Range("B" & Ligne) = Format(Now, "DD/MM/YY HH:MM:SS")
    .Range("C" & Ligne) = Target.Address
    .Range("D" & Ligne) = Target.Cells(1, 1)
  End With
End Sub

Bonjour Banzai,

Merci bcp, j'ai fait la copie. Je vais faire un essai dans la matinée, j'ai hâte de voir ce que ça donne.

Je te souhaite une bonne journée.

VALOU

Re-bonsoir Banzai,

Merci, ça fonctionne, si je peux me permettre, serait-il possible (j'imagine que oui) d'ajouter en plus comme information le nom de la feuille où se trouve la modification :

Tu m'as donnée cette macro à recopier, quel pourrait être le complément ? .Range("E" & Ligne) = ..... ??? c'est là que je coince. Merci encore. VALOU

Private Sub Worksheet_Change(ByVal Target As Range)

Dim Ligne As Long

With Sheets("DATES MODIFS")

Ligne = .Range("A" & Rows.Count).End(xlUp).Row + 1

.Range("A" & Ligne) = Application.UserName

.Range("B" & Ligne) = Format(Now, "DD/MM/YY HH:MM:SS")

.Range("C" & Ligne) = Target.Address

.Range("D" & Ligne) = Target.Cells(1, 1)

End With

End Sub

Bonsoir

Il faut supprimer la macro en place dans le module de la feuille

Mets cette macro dans le module ThisWorkbook

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim Ligne As Long
  If Sh.Name <> "DATES MODIFS" Then   ' Attention il faut le même nom
    With Sheets("DATES MODIFS")
      Ligne = .Range("A" & Rows.Count).End(xlUp).Row + 1
      .Range("A" & Ligne) = Application.UserName
      .Range("B" & Ligne) = Format(Now, "DD/MM/YY HH:MM:SS")
      .Range("C" & Ligne) = Sh.Name
      .Range("D" & Ligne) = Target.Address
      .Range("E" & Ligne) = Target.Cells(1, 1)
    End With
  End If
End Sub

Bonjour et merci Banzai, c'est bien ce que je souhaitais.

Bonne journée à toi, sous la neige !

VALOU