Inversion de valeurs pour le calcul d'une moyenne ?

Bonjour à toutes et à tous,

Dans le cadre de mes études, je réalise actuellement une enquête concernant le bizutage, basée sur le modèle du Big Five (modèle psychologique). J'ai utilisé les outils mis à disposition par Google et les résultats sont estampillés sous la forme d'une feuille de calcul.

Le questionnaire comprend 45 questions afin de distinguer cinq traits centraux de la personnalité (qui sont l'extraversion, le névrosisme, l'agréabilité, la conscience et l'ouverture à l'expérience).

Pour faire bref, le sujet répond à différentes questions sur une échelle de 1 à 5 et on calcule ensuite la moyenne des réponses afin de situer les tendances de sa personnalité. Aucun soucis pour le calcul de la moyenne mais un problème se pose puisque la valeur de certaines réponses sont "renversées". Ainsi, pour ces fameuses questions, les réponses équivalent à 1=5 ; 2=4 ; 3=3 ; 4=2 ; 5=1.

Je n'ai pas la maitrise suffisante d'excel pour mettre en place cela, mais je sais que cela est possible par le biais, me semble-t-il, de conditions. Mes recherches n'ont jusque là pas été fructueuses, c'est pourquoi je fais appel à votre aide.

Si quelqu'un pouvait me renseigner, je lui en serais très reconnaissant.

Merci par avance, et bon week-end à vous tous.

Salut et bienvenue sur le forum,

Admettons que ta colonne B soit une colonne à renverser. Dans la colonne BI du fichier ci-joint, je te montre comment tu peux inverser les résultats de la colonne B avec la formule

=CHOISIR(EQUIV(B2;{1;2;3;4;5});5;4;3;2;1)

placée en BI2, incrémentée vers le bas.

Cette même possibilité est utilisée en BJ2, combinée avec le reste de ta formule et également incrémentée vers le bas.

Comme toujours avec Excel, il existe de très nombreuses variantes. Comme tu as proposé d'utiliser la fonction SI, je te montre une possibilité en colonne BO, mais c'est quand même - selon moi - moins élégant

=SI(B2=1;5;SI(B2=2;4;SI(B2=4;2;SI(B2=5;1;3))))

A te relire.

Bonjour

En concaténant les plages, on obtient la suite des chiffres et non plus l'addition de ceux-ci

Ta formule en BJ2

=B2+L2+Q2+AA2+AK2

fait la somme de ces celules soit 2+3+2+2+3

La formule

=B2&L2&Q2&AA2&AK2 

affiche la concaténation 23223

on compte le nombre de chiffres 1 à 5 et multiplie par la valeur attribuée.

On obtiens par exemple en BJ2 la formule

=(NBCAR(B2&L2&Q2&AA2&AK2)-NBCAR(SUBSTITUE(B2&L2&Q2&AA2&AK2;1;"")))*5+(NBCAR(B2&L2&Q2&AA2&AK2)-NBCAR(SUBSTITUE(B2&L2&Q2&AA2&AK2;2;"")))*4+(NBCAR(B2&L2&Q2&AA2&AK2)-NBCAR(SUBSTITUE(B2&L2&Q2&AA2&AK2;3;"")))*3+(NBCAR(B2&L2&Q2&AA2&AK2)-NBCAR(SUBSTITUE(B2&L2&Q2&AA2&AK2;4;"")))*2+(NBCAR(B2&L2&Q2&AA2&AK2)-NBCAR(SUBSTITUE(B2&L2&Q2&AA2&AK2;5;"")))

qui donne 18

je ne sais si on peut simplifier, vu l'heure, je ne me suis pas attelé à cette question.

Ton fichier en retour

Cordialement

Bonsoir,

Pour inverser des notes en A par exemple, insérer une colonne et :

=6-A1

à recopier vers le bas.

Ou bien faire l'opération dans la formule de somme sur les colonnes concernées. Par exemple :

=B2+L2+(6-Q2)+AA2+(6-AK2)

ce qui revient à soustraire les colonnes concernées et ajouter x fois 6 :

=B2+L2-Q2+AA2-AK2 +12

eric

eriiic a écrit :

ce qui revient à soustraire les colonnes concernées et ajouter x fois 6 :

=B2+L2-Q2+AA2-AK2 +12

Merci beaucoup à vous tous, c'est parfait, vous m'êtes d'un précieux service. J'ai adopté la méthode d'éric, plus simpliste, mais j'ai regardé vos autres commentaires et cela me permet de mieux comprendre le fonctionnement et les étendues de ce logiciel..

Vraiment un super site, merci de m'avoir accordé un peu de votre temps !