Problème de remplissage Textboxs

Bonjour , je vous soumet un nouveau problème :

Je saisie un indice dans le textbox9 , dans la feuille HEURE_ROSE il faut retrouver cet indice et répartir les horaires trouvés dans les autres textbox.

Si j'ai un seul indice retrouvé dans la feuille HEURE_ROSE les textbox 69 ,70 , 71 , 72 se remplissent quand même:

Comment éviter ce remplissage inapproprié ?

Private Sub TextBox9_Change()
Dim c As Range ' Recherche dans la feuille HEURE_ROSE  les  horaires
Set c = Sheets("HEURE_ROSE").Range("B:B").Cells.Find(What:=Me.TextBox9)

If Not c Is Nothing Then Me.TextBox67 = c.Offset(0, 2).Value
If Not c Is Nothing Then Me.TextBox68 = c.Offset(0, 4).Value
If Not c Is Nothing Then Me.TextBox69 = c.Offset(1, 2).Value
If Not c Is Nothing Then Me.TextBox70 = c.Offset(1, 4).Value
If Not c Is Nothing Then Me.TextBox71 = c.Offset(2, 2).Value
If Not c Is Nothing Then Me.TextBox72 = c.Offset(2, 4).Value

Me.TextBox67 = Format(Me.TextBox67, "hh:mm")
Me.TextBox68 = Format(Me.TextBox68, "hh:mm")
Me.TextBox69 = Format(Me.TextBox69, "hh:mm")
Me.TextBox70 = Format(Me.TextBox70, "hh:mm")
Me.TextBox71 = Format(Me.TextBox71, "hh:mm")
Me.TextBox72 = Format(Me.TextBox72, "hh:mm")

End Sub

Merci pour votre aide

Salut Isabellette,

Toujours ces fichus horaires

Je ne trouve pas de TextBox dans ton fichier

Cordialement.

NB : Si ton fichier n'est pas si gros, postes-le avec les outils du Forum, c'est quand même plus simple à consulter (et avant de poster un fichier sur C-Joint, essaie encore de le compresser).

Voici un classeur comprimer en un résumé :

Bonjour

Essayes cette macro

Option Explicit

Private Sub TextBox9_Change()
Dim C As Range              ' Recherche dans la feuille HEURE_ROSE  les  horaires
Dim I As Integer
Dim Depart As String

  For I = 67 To 72
    Me.Controls("TextBox" & I) = ""
  Next I
  With Sheets("HEURE_ROSE").Columns("B")
    Set C = .Find(What:=Me.TextBox9, LookIn:=xlValues, LookAt:=xlWhole)
    If Not C Is Nothing Then
      Depart = C.Address
      I = 67
      Do
        Me.Controls("TextBox" & I) = C.Offset(0, 2).Value
        Me.Controls("TextBox" & I + 1) = C.Offset(0, 4).Value
        Me.Controls("TextBox" & I) = Format(Me.Controls("TextBox" & I), "hh:mm")
        Me.Controls("TextBox" & I + 1) = Format(Me.Controls("TextBox" & I + 1), "hh:mm")
        I = I + 2
        Set C = .FindNext(C)
      Loop While C.Address <> Depart
    End If
  End With
End Sub

Bonjour , c'est super cela fonctionne bien.

Encore MERCI