Imprimer un fichier pdf depuis une commande Excel

Bonjour

Existe t il unecommande qui permet d'imprimer un pdf situer dans un dossier a partir d'une commande excel?

Bonjour,

Avec une macro de silkyroad :

Option Explicit

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
    (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" _
    (ByVal hWnd As Long, ByVal lpOperation As String, ByVal lpFile As String _
    , ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long

Sub ImprimerFichier()
    Dim NomFichier As String
    Dim x As Long

    x = FindWindow("XLMAIN", Application.Caption)
    NomFichier = "C:\dossier\rapport.pdf"

    ShellExecute x, "print", NomFichier, "", "", 1
End Sub

Code à coller dans un module.

Bonjour,

J'ai bien réussi à tester cette macro sur mon PC et je dois dois dire que c'est vraiment parfait, mais j'ai un petit HIC, et oui il en faut un. J'ai réalisé un programme, avec cette macro, pour mon boulot sur un PC en 32 bit, le problème c'est que certains PC sont en 64 bits et ne peuvent pas utiliser ce programme.

Est-ce qu'il existe un moyen de faire cohabiter les deux systèmes ? La programmation n'est pas du tout mon métier et je n'ai pas de formation dans ce domaine. Pouvez-vous éclairer ma lanterne.

Salutations

Capyo25

Bonsoir,

A tester

Remplaces ton code par celui-ci.

A te lire car les questions Office 32 bits / 64 bits ne vont pas tarder à pleuvoir sur les forums.

Cdlt

' Test which version of VBA you are using.
#If VBA7 Then
   ' API function to locate a window.
   Declare PtrSafe Function FindWindow Lib "user32" _
      Alias "FindWindowA" ( _
      ByVal lpClassName As String, _
      ByVal lpWindowName As String) As LongPtr

    Private Declare PtrSafe Function ShellExecute Lib _
        "shell32.dll" Alias "ShellExecuteA" ( _
        ByVal hwnd As LongPtr, ByVal lpOperation As String, ByVal lpFile As String, _
        ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As LongPtr
#Else
   ' API function to locate a window.
   Declare Function FindWindow Lib "user32" _
      Alias "FindWindowA" ( _
        ByVal lpClassName As String, _
            ByVal lpWindowName As String) As Long

    Private Declare Function ShellExecute Lib _
        "shell32.dll" Alias "ShellExecuteA" ( _
            ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, _
                ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
#End If

Re,

Pour les explications sommaires, attendre demain

Bonjour à tous,

Merci Jean-Eric, je reviens vers toi dès que j'aurais modifié mon programme.

Salutations

Capyo25