Conversion Excel vers TXT

Bonjour,

Voilà mon projet final qui consiste à convertir des données Excel vers un fichier TXT, en prennent en considération des espaces bien déterminés entre les colonnes.

Ci-joint fichier Excel en objet, et le Fichier TXT portant en résultat deux lignes seulement.

Il s'agit en réalité de plus de 5000 lignes d'où la nécessité d'automatiser le travail.

Merci d'avance.

Salut,

Essaies ça :

Sub export()
Dim c As Range
Dim tempstr As String

Dim numfile As Integer
numfile = FreeFile

'************************************************************
'A MODIFIER
Open "c:\testexport.txt" For Output As #numfile
'For Each c In Selection 'Si appliquer a la selection
'************************************************************

For Each c In Range("A2", "A20") 'Appliquer a une plage fixe
    tempstr = c.Value  'On met la valeur de la premiere colonne
    tempstr = rempliespace(tempstr, 37) 'On ajoute des espaces => car n°37
    tempstr = tempstr & c.Offset(0, 1) 'On ajoute la valeur colonne B
    tempstr = rempliespace(tempstr, 60 - Len(CStr(Split(c.Offset(0, 2), ",")(0)))) 'On ajoute le nombre espace pour avoir tjs la , au bon endroit
    tempstr = tempstr & Format(c.Offset(0, 2), "###0.##") 'On ajoute la valeur colonne C
    tempstr = rempliespace(tempstr, 69) 'On ajoute des espaces => car n°69
    tempstr = tempstr & c.Offset(0, 3) 'on ajoute la valeur colonne D
    Print #numfile, tempstr
Next
Close #numfile 'Ferme le fichier
End Sub

Function rempliespace(chaine As String, nbblanc As Integer) As String
While Len(chaine) < nbblanc
    chaine = chaine & " "
Wend
rempliespace = chaine
End Function

Dis moi si cela correspond.

Damien

Bonjour

Bigdams merci, mais ça bloque juste sur open.

dois je crée le fichier d'abord ou bien il est généré automatiquement?

si je doit le crée dans un dossier nommé DOC qui est sur mon bureau, alors je modifie la ligne open ... comment?

Merci

Re

Pardon Bigdams, ça marche très bien, seulement j'avais une restriction sur la partition C.

C'est très gentil de votre part.

Cordialement