Compter mots différents sur une plage avec cellules vides
Bonjour,
j'aimerai pouvoir compter les N mots différents sur une plage donnée sans tenir compte des cellules vides, et des majuscules/minuscules.
Or la formule SOMMEPROD(1/NB.SI(PlageA;PlageA)) ne fonctionne pas lorsqu'il y a des cellules vides.
Connaissez vous une formule qui pourrait me dépanner ?
Merci d'avance
Riton26
Bonjour
Formule matricielle à valider avec les 3 touches ctrl+Maj+Entrée
=SOMMEPROD(SI(Plage<> "";1/NB.SI(Plage;Plage)))Cordialement
Merci, ca marche !
Maintenant, j'aimerai pouvoir compter le nombre de mots différents sur une plage, en tenant compte de 2 critères sur 2 autres plages du tableau.
J'ai écrit cette formule :
=SI(ET(A1:A50="Chocolat";B1:B50="Lait");SOMMEPROD(SI(C1:C50<>"";1/NB.SI(C1:C50;C1:C50))))Cependant le résultat obtenu n'est pas bon puisqu'il affiche "FAUX"
Avez vous une correction à me proposer ?
Merci,
Riton26
Bonjour
Toujours en saisie matricielle (Ctrl+Maj+Entrée)
=SOMME((FREQUENCE(SI($C$1:$C$50="";"";SI(SOUS.TOTAL(3;DECALER($A$1;LIGNE($C$1:$C$50);))*($A$1:$A$50="Chocolat")*($B$1:$B$50="Lait");EQUIV($C$1:$C$50;$C$1:$C$50;0)));LIGNE($C$1:$C$50))>0)*1)Cordialement
Merci encore Amadeus.
J'ai une derniere question (le relou....)
Une fois que tu sais qu'il y a X mots différents qui correspondent à tes 2 criteres de recherche dans la plage, comment fais tu pour les identifier et les mettre dans N cellules différentes. (1 mot par cellule)
Thanks!!
Bonjour
Là, c'est un peu plus délicat pour ajuster la formule.
Je t'ai donc fait le fichier exemple que tu n'as pas joint (Merci pour éventuellement la prochaine fois)
La formule toujours matricielle (sur le fichier en E5) à incrémenter vers le bas.
=INDEX($C$1:$C$51;MIN(SI(($A$2:$A$51="Chocolat")*($B$2:$B$51="Lait");SI(NB.SI(E$4:E4;$C$2:$C$51)=0;LIGNE($C$2:$C$51)))))&""Attention au premier champ et au dernier utilisés dans la formule!!
$C$1:$C$51 et $C$2:$C$51
Cordialement
Merci !
Sauf que lorsqu'on déplace le tableau ou la cellule de calcul, ça ne fonctionne plus... Ce qui n'est pas logique!
Je t'ai mit ton excel avec le tableau que j'ai bougé, ainsi que la cellule de calcul pour que tu vois le resultat...
Thanks
Bonjour
Sauf que lorsqu'on déplace le tableau ou la cellule de calcul, ça ne fonctionne plus... Ce qui n'est pas logique
Mais si! Sauf que pour respecter la logique, la formule Index cherche en fonction du No de Ligne de la Feuille et non du tableau.
INDEX($L$1:$L$61
Cordialement
Ah ouiiiii d'accord ! C'est bon ça marche !
Merci !!