Travail avec un userform et deux feuilles

Bonsoir,

J'ai un userform qui s'ouvre en sur ma feuille "VMA" . A l'interieur de cette userform j'ai une textbox. lorsque je remplis celui-ci j'aimerais qu'il effectue en fonction du resultat une recherche sur une seconde feuille "VamEval". Mais je ne peux passer d'une feuille à l'autre.

Voici mon code pour la textbox

Private Sub TextBox1_Change()

If Me.TextBox1.Value > 35 Then
MsgBox (" vous avez du vous trompé")
Else
Me.Label1.Caption = "Palier " & Me.TextBox1.Value
End If

With Sheets("VamEval")
REP9 = Me.Label1.Caption
Set R = Sheets("VamEval").Range("D:D").Find(REP9)
If R Is Nothing Then
Me.Label2.Caption = "Aucune valeur"
End If
If Not R Is Nothing Then
Col = Sheets("VamEval").Range("1:1").Find("VO2max").Column
Lig = Sheets("VamEval").Range("D:D").Find(Me.Label1.Caption).Row
Me.Label2.Caption = Cells(Lig, Col)
End If
End With
End Sub

Pour l'instant lorsque je remplis la textbox la recherche REP9 ne se fait pas et rien ne s’inscrit dans mon label2.

Débutant je manque de connaissance et je requiert donc un peu d'aide

Merci par avance.

Bonjour

Le mieux c'est que tu fournisses un fichier afin de tester

En attendant une erreur c'est que tu ne précises pas d'où vient

Me.Label2.Caption =Cells(Lig, Col)

Un code à tester (sans garantie car pas de fichier pour tester)

Private Sub TextBox1_Change()
Dim Cel As Range
Dim REP9 As String
Dim Lig As Long
Dim Col As Integer

  If Me.TextBox1.Value > 35 Then
    MsgBox (" vous avez du vous trompé")
  Else
    Me.Label1.Caption = "Palier " & Me.TextBox1.Value
  End If

  With Sheets("VamEval")
    REP9 = Me.Label1.Caption
    Set Cel = .Range("D:D").Find(what:=REP9, LookIn:=xlValues, lookat:=xlWhole)
       If Not Cel Is Nothing Then
      Col = .Range("1:1").Find(what:="VO2max", LookIn:=xlValues, lookat:=xlWhole).Column
      Lig = Cel.Row
      Me.Label2.Caption = .Cells(Lig, Col)
    Else
      Me.Label2.Caption = "Aucune valeur"
    End If
  End With
End Sub

Merci pour la réponse. Même sans avoir joint de fichier c'est exactement ce que je voulais. Merci pour avoir résolus mes deux problèmes.

Encore une fois parfait.