Inserer image dans tableau

Bonjour,

Je cherche a inserer une image dans la cellule d'un tableau.

Pour l'instant je travaille sur une simple cellule et voila ma formule

Sub pos_img()

ActiveSheet.Pictures.Insert("C:\Users\Thomas\Desktop\New folder\PSD.7z\PSD.7z\PSD\image.jpg").Select

With Selection

.ShapeRange.Left = ActiveCell.Left

.ShapeRange.Top = ActiveCell.Top

End With

End Sub

Ca marche comme il faut, sauf que je voudrais qu'il trouve le nom (ici image.jpg) tout seul, en allant chercher dans une autre cellule, qui devrait par la suite etre une cellule de tableau.

Plus tard il faudrait egalement par la suite reajuster automatique la taille de l'image.

Mauvaise nouvelle : je decouvre le VBA ce matin.

Merci beaucoup

Thomas

Bonjour CocoriCoy,

CocoriCoy a écrit :

Ca marche comme il faut, sauf que je voudrais qu'il trouve le nom (ici image.jpg) tout seul, en allant chercher dans une autre cellule, qui devrait par la suite etre une cellule de tableau.

ActiveSheet.Pictures.Insert("C:\Users\Thomas\Desktop\New folder\PSD.7z\PSD.7z\PSD\image.jpg").Select

par

ActiveSheet.Pictures.Insert("C:\Users\Thomas\Desktop\New folder\PSD.7z\PSD.7z\PSD\" & [A1]).Select

bonjour,

Essaie ainsi : (code commenté)

Sub insert_image()
Dim LePath As String, Limage As String
Dim NewImg As Object
Application.ScreenUpdating = False
LePath = ActiveWorkbook.Path & "\"  'détermine le répertoire contenant ton fichier
                                    'ainsi que tes images
Limage = Range("A1").Value          'le nom de l'image que tu veux insérer est dans
                                    'la cellule A1
Set NewImg = ActiveSheet.Pictures.Insert(LePath & Limage & ".jpg") 'insère l'image
With NewImg
    .ShapeRange.Left = ActiveCell.Left 'la positionne côté gauche
    .ShapeRange.Top = ActiveCell.Top   'la positionne en haut
    .Height = ActiveCell.Height        'hauteur de l'image = hauteur de la cellule
    .Width = ActiveCell.Width          'largeur de l'image = largeur de la cellule
End With
End Sub

bon courage dans ta découverte du VBA

Merci beaucoup pour toute ces infos ca marche niquel

J'ai une petite nuance a apporter, et si la cellule avec le nom de mon fichier n'est pas forcement tout le temps A1 mais quelque chose comme 3 cellule a gauche, puis 2 sur le dessus.

Merci encore

Thomas

Bonjour,

Limage = ActiveCell.Offset(2, 3).Value

Ici, le nom de l'image est situé 2 lignes en dessous, et 3 colonnes vers la droite, soit si tu es en A1, le nom est situé dans la cellule D4.

Si c'est ce que tu veux, sinon explique un peu mieux.

Bonne journée

C'est bien ce que je veux merci

Une derniere question, est ce que je peux appliquer cette technique sur un .doc au sein d'un tableau ?

Merci

Thomas

Bonsoir,

Je vais te répondre en 2 temps :

1/ Comment veux-tu insérer ton document word?

- Comme tel, avec tout le texte

- Comme un raccourci, sous forme d’icône?

2/ La réponse à ta question, tu peux la trouver tout seul, en utilisant l'enregistreur de macro..... Et en utilisant la syntaxe développée supra

Bon courage

Bonjour a tous

Je pense annuler le transition vers le .doc ca me semble un peu compliqué. Du moins pour l'instant.

Nouveau soucis , J'ai mon excel dans ce dossier :

\Desktop\PROJET\PREPA\06_Documents_de_correction

Je voudrais qu'il aille chercher des images là :

\Desktop\PROJET\PREPA\05_Storyboard\Screens

Il doit donc reculer d'un dossier, et evidement je ne peux pas mettre simplement le path dans mon code etant donné que le nom de PROJET change a chaque fois.

Bonjour tou(te)s,

A tester..

   LePath = Left(ThisWorkbook.Path, InStrRev(ThisWorkbook.Path, "\")) & "05_Storyboard\Screens\"

A+

Parfait, j'ai juste du remplacer ThisWorkbook par ActiveWorkbook

Merci beaucoup