Fonctions sumifs sumproduct et format date
Bonjour,
Voilà, je suis passé d'open office en francais à excel en anglais (j'habite à l'étranger) sur mac et je rencontre des problèmes avec les dates (et aussi les virgules, point virgules... mais ce n'est pas le pb).
J'avais une formule sumproduct
=SUMPRODUCT((belecole!$B$2:belecole!$B$564>=A13)*( belecole!$B$2:belecole!$B$564<=B13)*(belecole!$K$1 :belecole!$K$
A13 et B13 sont une date de début et de fin et le dernier critère une somme d'euros
Ca marchait très bien mais avec excel, pb VALUE dans la cellule.
Alors, je suis arrivé jusqu'à
=SUMPRODUCT((belecole!$B$2:$B$400>=A13);(belecole! $B$2:$B$400<=B13);belecole!$K$2:$K$564)
mais cela m'affiche toujours 0
Donc j'ai changé en mettant les dates directement 01/12/2010 et 31/12/2010. Pas mieux.
Alors j'ai essayé avec la fonction SUMIFS
=SUMIFS(belecole!K2:K400;belecole!B2:B400;">=A13"; belecole!B2:B400;"<=B13")
Toujours 0
Mais avec
=SUMIFS(belecole!K2:K400;belecole!B2:B400;">=01/12/2010";belecole!B2:B400;"<=31/12/2010")
Ca marche: j'ai bien 4500 qui s'affiche!
Je sens un pb de date en français, anglais mais ne m'en sors pas, surtout avec SUMPRODUCT. Je voudrais ne pas saisir en dur les dates.
Merci d'avance.
J'espère que c'est clair.
Patrick
J'ajoute que mes cellules où il y a des dates sont au format DATE french.
Encore merci.
Bonjour,
cette formule =SUMPRODUCT((belecole!$B$2:$B$400>=A13);(belecole! $B$2:$B$400<=B13);belecole!$K$2:$K$564)
ne peut pas fonctionner avec Excel (contrairement à Calc).
Il faut pour cela convertir les VRAI/FAUX en 1/0
Par exemple comme ceci :
=SUMPRODUCT((belecole!$B$2:$B$400>=A13)*(belecole! $B$2:$B$400<=B13);belecole!$K$2:$K$564)
ou
=SUMPRODUCT((belecole!$B$2:$B$400>=A13)*1;(belecole! $B$2:$B$400<=B13)*1;belecole!$K$2:$K$564)
ou
=SUMPRODUCT(N(belecole!$B$2:$B$400>=A13);(Nbelecole! $B$2:$B$400<=B13);belecole!$K$2:$K$564)
ou
=SUMPRODUCT(--(belecole!$B$2:$B$400>=A13);--(belecole! $B$2:$B$400<=B13);belecole!$K$2:$K$564)
et sans doute d'autres variantes.
Si tu obtiens #VALUE! c'est sans doute parce que la colonne B ne contient pas seulement des dates mais aussi
des cellules vides, du texte, une valeur d'erreur ....
Mais là, un spécialiste d'Excel pourra t'en dire plus.
Concernant SUMIFS, tu fais une erreur de syntaxe :
=SUMIFS(belecole!K2:K400;belecole!B2:B400;">=A13"; belecole!B2:B400;"<=B13")
Tu ne dois pas mettre les références aux cellules A13 et B13 entre guillemets. Ceci doit fonctionner :
=SUMIFS(belecole!K2:K400;belecole!B2:B400;">="&A13; belecole!B2:B400;"<="&B13)
A vérifier (je n'ai pas Excel).
A+
Un grand merci!
Bravo! Sans avoir excel, tu as débrouillé mon affaire!! Chapeau bas.
Tes 2 solutions fonctionnent.
Merciiiii.