Nom d'Onglet => Valeur Cellule

Bonjour,

Encore un truc avec mes Onglets.

Je voulais attribuer le nom de l'Onglet à une cellule.

Exemple :

Nom de L'Onglet = bâtiment

Cellule A1 prend la valeur texte = bâtiment

Quelle sera la fonction de la cellule A1 ?

Rien de très compliqué pour vous les chevronnés d'Excel.

Merci d'avance

Bonsoir

Formule dans la cellule

=STXT(CELLULE("nomfichier");TROUVE("]";CELLULE("nomfichier"))+1;50)

Le 50 prévoit un nom de 50 caractères maxi..ou

=STXT(CELLULE("nomfichier");TROUVE("]";CELLULE("nomfichier"))+1;NBCAR(CELLULE("nomfichier")))

ou

=DROITE(CELLULE("nomfichier");NBCAR(CELLULE("nomfichier"))-TROUVE("]";CELLULE("nomfichier")))

ou

=STXT(CELLULE("nomfichier");CHERCHE("]";CELLULE("nomfichier");1)+1;NBCAR(CELLULE("nomfichier"))-CHERCHE("]";CELLULE("nomfichier")))

d'autres détails:

https://www.excel-pratique.com/forum/viewtopic.php?t=1415&start=0&postdays=0&postorder=asc&highlight=

Cordialement

Déjà résolu !

Trop fort ce site ! Vraiment, toujours une solution donnée.

Bravo et merci de l'aide Amadéus

Je vous prépare une autre...

Salutaions.

Bonsoir,

Quand - même un petit probleme.

Toutes les cellules A1 dans chaque Feuille prend la valeur de l'onglet de la feuille active

Je souhtais que chaque feuille, dans la cellule A1 prend la valeur de son propore Onglet.

Solution ?

Salut le forum

Acpr avec le titre [Résolu] Nom d'Onglet => Valeur Cellule, tu risquais que ta ficelle passe inaperçue.

Voila une solution par macro, dans ThisWorbook (valide pour toutes les feuilles)

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
[A1] = Sh.Name
End Sub

Mytå

Bonjour Amadeus, Bonjour le forum

Amadéus a écrit :

Formule dans la cellule

=STXT(CELLULE("nomfichier");TROUVE("]";CELLULE("nomfichier"))+1;50)

Le 50 prévoit un nom de 50 caractères maxi..ou

=STXT(CELLULE("nomfichier");TROUVE("]";CELLULE("nomfichier"))+1;NBCAR(CELLULE("nomfichier")))

ou

=DROITE(CELLULE("nomfichier");NBCAR(CELLULE("nomfichier"))-TROUVE("]";CELLULE("nomfichier")))

ou

=STXT(CELLULE("nomfichier");CHERCHE("]";CELLULE("nomfichier");1)+1;NBCAR(CELLULE("nomfichier"))-CHERCHE("]";CELLULE("nomfichier")))

Pour obtenir le nom de l'onglet de sa propre feuille, sans passer par une macro, il suffit de placer le nom d'une cellule de la feuille dans la fonction CELLULE.

Cela donne, par exemple, CELLULE("nomfichier";$A$1) à la place de seulement CELLULE("nomfichier") dans toutes les formules données par Amadeus.

Encore une fois, bravo Amadeus et les autres pour toutes les solutions données sur ce site.

Salutations

Dan

Bonjour à tous

La solution VB marche mais, il est vrai que j'aurais souhaité d'éviter les VB dans ce dossier.

Mais, l'essentiel est que ça marche.

Merci.