Problème avec formule SOMMEPROD
Bonjour,
Avant d'expliquer mon problème, voici un petit apercu de mon tableau:
En colonne C, j'ai une longue liste de magasins du type avec chacun un nom du type enseigne + ville
En colonne I se trouve le montant des commandes par magasins
A la fin de mon tableau, j'ai un recap du chiffre d'affaire total par groupe (et non par enseigne) obtenu via la formule SOM.SI
Problème: un de ces groupes posséde plusieurs enseignes.
Il me semble donc que je dois utiliser la formule SOMMEPROD afin de cumuler le chiffre d'affaire des enseignes de ce meme groupe. Cependant, cela ne marche pas, j'obtiens une erreur...
Voici la formule que j'utilise:
=SOMMEPROD((C2:C3000="*ENSEIGNE1*")*(C2:C3000="*ENSEIGNE2*")*(I1:I3000))
Les noms des magasins étant du type ENSEIGNE + VILLE et les villes étant bien entendu différentes et ne devant pas influer sur le calcul du chiffre d'affaire, je souhaite que seul les ENSEIGNES soient prise en compte.
Un grand merci par avance pour votre aide.
Bonjour,
Je ne suis pas sur que les étoiles soient prises en compte dans la formule, peux-tu séparer et faire une colonne avec ton nom d'enseigne et une colonne avec le nom de la ville?
Ensuite pour une seule enseigne, je te conseille la formule suivante :
=SOMMEPROD((C2:C3000="ENSEIGNE1")*(I1:I3000)) donne le montant de l'enseigne1 si dans dans la colonne il y ai marqué "ENSEIGNE1" exactement.
Bonjour,
Merci pour ta réponse. Malheureusement, il n'y a pas marqué uniquement ENSEIGNE1 mais ENSEIGNE1 + VILLE.
C'est pour cela que j'utilise des * pour encadrer les textes.
Par ailleurs, je souhaite le chiffre d'affaire de toutes les lignes avec ENSEIGNE1 mais aussi ENSEIGNE2
Je dois donc cumuler deux arguments.
Merci quand meme pour ton aide.
-- 24 Juin 2011, 17:28 --
Excuse mopi, je n'avais pas lu la premiere phrase. Je n;ai malheureusement pas la possibilité de changer le format du fichier. Il doit rester du type ENSEIGNE + VILLE.
Pour mes foumles SOM.SI, le symbole * fonctionne afin de chercher un mot parmi une cellule.
Bonjour,
un ptit fichier exemple serait génial,
sinon au moins un exemple de la syntaxe de cette colonne double info, y'a t'il un séparatif entre l'enseigne et la ville ?
Bonjour,
Un essai avec ce que j'ai compris :
=SOMMEPROD((ESTNUM(CHERCHE("ENSEIGNE1";C2:C3000)))+(ESTNUM(CHERCHE("ENSEIGNE2";C2:C3000)))*(I2:I3000))@+
Bonjour,
Merci à Misterno et Thibo pour vos réponses.
Thibo, tu as bien compris ce que je voulais faire mais malheureusement je n'obtiens pas le bon résultat.
Je viens d'attacher un fichier exemple pour une meilleure compréhension du problème.
Merci à vous
re,
Petit problème de parenthèses.
Essaye avec cette formule :
=SOMMEPROD((ESTNUM(CHERCHE("ENSEIGNE1";C5:C12))+ESTNUM(CHERCHE("ENSEIGNE2";C5:C12)))*(I5:I12))@+
Bonjour,
juste une petite correction :
=SOMMEPROD((ESTNUM(CHERCHE("ENSEIGNE1";C5:C12)))*(I5:I12))
et
=SOMMEPROD((ESTNUM(CHERCHE("ENSEIGNE2";C5:C12)))*(I5:I12))
voilà ...
Un grand merci, c'est parfait!!! (solution de Thibo avec tout en une formule)
Bonjour,
Je suis vraiement désolé de revenir sur ce sujet aujourd'hui mais en voulant utliser cette formule qui marchait hier sur mon excel perso, impossible de la faire fonctionner sur mon excel du travail (en neerlandais). Je pense pourtant avoir trouvé les bonnes traductions des formules... J'ai beau bidouillé, je n'y arrive pas...
Quelqu'un pourrait-il jeter un oeil à ma PJ?
Merci par avance.
Bonjour,
Je te propose cette formule :
=SOMMEPROD((ESTNUM(CHERCHE("ENSEIGNE*1";C5:C12))+ESTNUM(CHERCHE("ENSEIGNE*2";C5:C12)))*(I5:I12))Je joins le fichier pour que la traduction se fasse en néerlandais (voir la cellule jaune).
J'ai mis un * entre Enseigne et 1 (ainsi que 2). Dans ton premier exemple, il n'y avait pas d'espace. Dans ton dernier fichier, il y en a un. Avec le *, peu importe qu'il y ait un espace ou pas.
@+
Edit : Il faut quand même privilégier l'espace à la place de *. Sinon, Excel fait une confusion avec Enseigne 1 et Enseigne 11 par exemple.
@+
Bonjour Thibo,
Merci encore une fois. Avant de confirmer la résolution du problème, je vais vérifier demain sur ma version NL.
A+
Bonjour,
Thibo, je viens d'essayer la nouvelle formule que tu m'as donnée mais j'ai encore quelques problèmes sur mon fichier du travail.
Dans le fichier sur lequel je souhaite appliquer cette formule, la colonne I comprend parfois du texte et ceci a pour conséquence que la formule me renvoie #VALEUR!
La formule marche uniquement si la colonne I ne comprend que des chiffres. Je pensais cependant que la formule ignorerait les celulles comportant du texte mais ca ne semble pas etre le cas...
Voir en exemple la PJ.
En esperant que tu puisses m'aider... Merci encore.
Bonjour,
Remplace le dernier * par un ; (ou une virgule selon ta version NL) :
=SOMMEPROD((ESTNUM(CHERCHE("ENSEIGNE*1";C5:C14))+ESTNUM(CHERCHE("ENSEIGNE*2";C5:C14)));I5:I14)@+
Bonjour Thibo,
Merci, cette fois, tu as définitivement solutionné mon problème.
Vraiment un grand merci!
A+