NB.SI et SOUS.TOTAL
Bonjour à tous,
j'ai beau essayer les formules proposées sur le site, dans tous les sens, je ne parviens pas à déterminer la formule qui me permettra de calculer le nombre de valeurs >x dans une colonne lorsque je filtre les critères dans mes 6 colonnes précédentes.
Quelqu'un pourrait-il m'aider svp? J'ai bien compris que SOUS.TOTAL et NB.SI n'étaient pas compatibles alors comment faire?
merci d'avance
Edit Dan : Supprimé "Help" dans titre du sujet
Bonjour,
Avec cette formule --> =SOUS.TOTAL(109;A2:A50)
avec A2:A50 : la colonne complète des données
Si ok merci de ne pas oublier pas de cliquer sur le V vert pour cloturer le fil.
Amicalement
Merci Dan,
mais cette formule ne résoud que 50% de mon problème. Je veux en plus ne comptabiliser que les valeurs supérieures à 2.
Bonjour
Adapte cette formule à ton fichier.
Là, j'ai considéré que les titres étaient en lignes 1 et que G est la colonne contenant les chiffres
=SOMMEPROD((SOUS.TOTAL(3;DECALER($G$1;LIGNE(INDIRECT("1:"&LIGNES($A$2:$A$65536)));)))*($G2:$G65536>2))Amicalement
Nad
Merci Nad,
juste encore quelques précisions car pour le moment il accepte la formule mais le résultat est faux:
=SOMMEPROD((SOUS.TOTAL(3;DECALER($G$1;LIGNE(INDIRECT("1:"&LIGNES($A$2:$A$65536)));)))*($G2:$G65536>2))
Donc si je comprends bien, ce que je peux modifier:
$G$1 = cellule de titre de la colonne dans laquelle se trouve mes valeures à décompter (en l'occurence $J$8 pour la 1e)
$G2:$G65536>2 = plage de la colonne dans laquelle se trouve mes valeures à décompter (en l'occurence $J9:$J218>2)
mais que représente la référence à la colonne A?
et le "1" suivant le INDIRECT est-il un code ou une référence. Dans ce cas, par quoi dois-je le remplacer?
A savoir, j'aurais besoin ensuite de tirer cette formule sur 350 colonnes en 2 onglets
d'avance merci pour tes réponses complémentaires
Re
Caroline29 a écrit :$G$1 = cellule de titre de la colonne dans laquelle se trouve mes valeures à décompter (en l'occurence $J$8 pour la 1e)
$G2:$G65536>2 = plage de la colonne dans laquelle se trouve mes valeures à décompter (en l'occurence $J9:$J218>2)
OUI
Caroline29 a écrit :mais que représente la référence à la colonne A?
Le A peut être remplacé par n'importe quelle colonne - Aucune importance
Caroline29 a écrit :et le "1" suivant le INDIRECT est-il un code ou une référence. Dans ce cas, par quoi dois-je le remplacer?
Le INDIRECT("1:" doit rester
De ce que tu expliques sur ton tableau, la formule doit donner :
1 - Le nombre de lignes est de 218 et ne va pas évoluer :
=SOMMEPROD((SOUS.TOTAL(3;DECALER(J1;LIGNE($9:$218)-1;)))*(J9:J218>2))2 - Le nombre de lignes peut évoluer
=SOMMEPROD((SOUS.TOTAL(3;DECALER(J8;LIGNE(INDIRECT("1:"&LIGNES($A$9:$A$65536)));)))*(J9:J65536>2))Si pas bon, merci de joindre ton fichier
Nad
Voilà mon fichier. J'ai du le réduire pour pouvoir l'attacher. A savoir:
1° Je suis susceptible de filtrer les colonnes D à I
2° Les évaluations à partir de la colonne J vont de 0 à 4, parfois, la cellule sera vide.
3° Ce qui m'intéresse, c'est que en ligne 119 j'obtienne le total des valeurs supérieures à 2 pour chacun des filtres ou combinaison de filtre que je pourrais appliquer.
4° Fyi: ma ligne 121 correspond au total des valeurs supérieures à 2 pour toute la colonne.
Merci d'avance pour ta précieuse aide
Re
Dans le fichier actuel, la dernière ligne à prendre en compte est la 116.
Comme dit précédemment, si la dernière ligne ne doit pas bouger, tu peux utiliser :
=SOMMEPROD((SOUS.TOTAL(3;DECALER(J1;LIGNE($9:$116)-1;)))*(J9:J116>2))Tu remplaces le 116 par 218 dans ton fichier réel.
Nad
Ca marche, c'est topissime
Merci beaucoup et bon week end prolongé!