COndition dans boucle For

Bonjour,

J'ai un souci avec le code suivant:

Sub Copie_codes_couleur()

Sheets("Aide saisie").Select
Range("B1:B4").Select
Selection.Copy

Dim i As Long
For i = 1 To Worksheets.Count
    Sheets(i).Activate
    If (ActiveSheet.Name = "RECAP") Or (ActiveSheet.Name = "Aide saisie") Or (ActiveSheet.Name = "Page de garde") Or (ActiveSheet.Name = "Suivi 60632") Then 
    'que dois-je mettre ici ?    
    End If

    ActiveSheet.Range("A8:A11").Select
    Selection.PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, _
        SkipBlanks:=False, Transpose:=False

 Next

End Sub

Je souhaiterais copier la mise en forme de la sélection B1:C4 de l'onglet "Aide saisie" aux celleules A8:A11 de tous les autres onglets du classeur excepté les onglets "RECAP", "Page de garde", "Suivi 60632" et donc "Aide Alizé".

Mais je ne sais pas comment spécifier cette exception...

Si quelqu'un à une idée, je suis preneur. Merci.

Aurélien.

Bonjour,

essaye avec

Sub Copie_codes_couleur()
Dim SansTr, i%
    SansTr = Array("RECAP", "Aide saisie", "Page de garde", "Suivi 60632")

    For i = 1 To Worksheets.Count
        If IsError(Application.Match(Worksheets(i).Name, SansTr, 0)) Then
            Sheets("Aide saisie").Range("B1:B4").Copy
            Worksheets(i).Range("A8:A11").PasteSpecial Paste:=xlPasteFormats, _
            Operation:=xlNone, SkipBlanks:=False, Transpose:=False
            Application.CutCopyMode = False
        End If
    Next
End Sub

Amicalement

Claude

Merci Claude, ça fonctionne à merveille !

Bonjour,

j'ai oublié "Aide Alizé" sur cette ligne

    SansTr = Array("RECAP", "Aide saisie", "Page de garde", "Suivi 60632")

à noter:

éviter les espaces dans les noms

Amicalement

Claude

No worries, c'est ok. C'était une coquille de ma part

Pourquoi les espaces sont à éviter ? Ca peut poser problème pour l'exécution des macros ?

re,

c'est un conseil

"Page de garde"

1) tu risque de mettre en + ou d'oublier un espace

2) dans les formules Nom/Défini, Excel écriera systématiquement "Page_de_garde"

éviter aussi les noms à rallonge (source d'erreur)

J'aurai écris: "PageGarde"

Ceci n'est qu'un avis perso.

Claude

J'en prends bonne note, merci !

Aurélien.