Mette en gras un mot

Bonjour à vous amis excelliens,

Voici ma question : Ce que j’aimerais, c’est dans une feuille mettre en gras un mot bien précis se trouvant sur des lignes, à chaque fois que ce mot apparaît qu’il se mette directement en gras, merci d’avance

exemple :

Etc...

Bonjour,

Les lignes sont purement du texte ou des formules

Dans le 1er cas, c'est possible, dans le second non
Sinon voici le code donné par Perplexity

Sub MettreMotEnGras()
    Dim ws As Worksheet
    Dim c As Range
    Dim motCible As String
    Dim pos As Long

    Set ws = ThisWorkbook.Worksheets("Feuil1")  ' nom de la feuille
    motCible = "TEST"                           ' mot à mettre en gras

    ' Parcours de toutes les cellules non vides de la colonne A
    For Each c In ws.Range("A1:A1000").Cells
        If c.Value <> "" Then

            ' On enlève d'abord le gras sur tout le texte (optionnel)
            c.Font.Bold = False

            pos = InStr(1, c.Value, motCible, vbTextCompare)
            Do While pos > 0
                ' Met en gras uniquement le mot trouvé
                c.Characters(Start:=pos, Length:=Len(motCible)).Font.Bold = True
                ' Recherche de l'occurrence suivante dans la même cellule
                pos = InStr(pos + Len(motCible), c.Value, motCible, vbTextCompare)
            Loop
        End If
    Next c

End Sub

A+

Bonjour à tous,

Une p'tite macro de ma pomme. Cliquer sur le bouton Hop !

Le code dans le module associé à Feuil1:

Sub EnGras()
Const Mot = "heureux", RespecterCasse = True, Plage = "b1:c999"
Dim xrg As Range, xcell As Range, TailMot&, casse, v, n&, deb&
   TailMot = Len(Mot): casse = IIf(RespecterCasse, vbBinaryCompare, vbTextCompare)
   On Error Resume Next
   Set xrg = Range(Plage).SpecialCells(xlCellTypeConstants, xlTextValues)
   If xrg Is Nothing Then Exit Sub
   Application.ScreenUpdating = False
   For Each xcell In xrg
      v = xcell.Value: deb = 1
      Do
         n = InStr(deb, v, Mot, casse)
         If n > 0 Then xcell.Characters(Start:=n, Length:=TailMot).Font.Bold = True: deb = n + TailMot
      Loop Until n = 0 Or deb > Len(v)
   Next xcell
End Sub

Je suis désolé, mais moi et les macros, je n'y connais rien et sans macro est-ce possible ?

xddrmcsy a écrit: Je suisdésolé, mais moi et les macros, je n'y connais rien et sans macro est-ce possible ?

Sans macro je ne le pense pas. Et d'ailleurs, je n'ai jamais croisé aucune méthode pour le faire sans macro.

Bonjour à tous !

bien sûr que si sans macro cela existe : c'est à l'huile de coude ! A moins qu'une solution Power Querry puisse jouer sur les mises en formes...
pour moi les deux codes sont bon et simple à mettre en œuvre à moins que l'extension xlsM soit interdit où vous avez besoin de ce fichier...

@ bientôt

LouReeD

Salut

LouReeD a écrit :

Bonjour à tous !

bien sûr que si sans macro cela existe : c'est à l'huile de coude !

LouReeD

Il faudra nous montrer LouReeD, je suis curieux

Hello,

xddrmcsy a écrit: Je suis désolé, mais moi et les macros, je n'y connais rien ?

il n'est pas nécessaire d'en savoir beaucoup pour utiliser une macro . Il faut savoir seulement ouvrir l'éditeur VBA , créer un module et coller dedans le code que quelqu'un a concocté. Par exemple pour ton cas, la macro est déclenchée par un bouton dans une feuille et dans une feuille de paramètre, tu as le ou les mots que tu veux mettre en gras (dans une cellule nommée MotsEnGras par exemple) et dans la feuille de données , une plage nommée Data qui contient les lignes où tu veux mettre des mots en gras). Pour les Mots en gras tu peux en avoir plusieurs séparés par une virgule ou aussi rien si tu ne veux aucun mot en gras.

Ami calmant, J.P

OK, ça marche grâce à toi, je te remercie, moi qui n'osez pas me lancer dans les macros et bien j'ai enfin compris, il faut dire que je suis pas un expert en informatique, merci à tous ceux qui m'ont aidé avec leur formule, encore merci à vous tous