Insertion texte et Somme dynamique variable

Bonjour à tous,

Je viens chercher vos lumières concernant deux ou trois soucis.

Insertion texte

En E4 j’ai une série de chiffres (qui est variable) que je voudrais ajouter à la fin d’une phrase en BM4 juste après « J'accepte votre devis numéro »

En VBA ça peut jouer, s'il n'y a pas d'autre solution.

Somme dynamique

Dans le tableau à partir de la ligne 49, je ne vois pas trop comment faire…

Il y a deux cas de figure qui peuvent arriver : soit j’ai des sous-totaux (comme dans l’exemple).

Et dans ce cas, tous les sous-totaux doivent additionner leur liste, puis renvoyer la somme totale sur BD13.

Le souci, c’est que la position de sous-total n’est pas fixe, liste déroulante en colonne D

Deuxième cas de figure : il n'y a aucun sous-total et toute la colonne F doit être additionnée sur BD13.

Idéalement dynamiquement sans VBA.

Je vous joins le fichier, je tourne sur Office 360

Attention c'est un type Modele.

Bonjour,

Pour votre 1ère demande, il suffit de créer une formule avec retour à la ligne forcée car(10)

="Validité du devis :" & CAR(10)
&"3 mois après la date d'émission." & CAR(10)
&CAR(10)
&"Paiements :" & CAR(10)
&"40% à la commande" & CAR(10)
&"50% à l'achèvement de 80% des travaux" & CAR(10)
&"10% à la réception des travaux selon normes SIA art. 158 al. 2" & CAR(10)
&"Échéance 14 jours après la date de la facture, net." & CAR(10)
&CAR(10)
&"Pour acceptation, merci d'envoyer un mail avec la mention :" & CAR(10)
&"J'accepte votre devis numéro " & E4 & CAR(10)
&"Ou nous retourner ce devis daté et signé." & CAR(10)
&CAR(10)
&CAR(10)
&"Date :                                                        Signature :"

Pour la 2ème ce sera VBA, pas le choix, mais je ne le ferais pas à votre place

Cordialement

Bonjour,

Puisque JExcelFr vous a répondu sur la question1, je m'occupe de la deuxième

Pour la question 2, sur office 365 on peut s'en sortir avec des formules.

Pour les sous-totaux dans le tableau, entrez ceci en colonne F (cellule F49 précisément, et remplacez la colonne calculée par cette nouvelle formule) :

=SI(
    [@Colonne3] <> "sous-total";
    SI([@Colonne2] > 0; SOMME([@Colonne2] * [@Colonne4]); "");
    LET(
        _idST; SCAN(1; $D$47:$D48; LAMBDA(a; v; a + 1 * (v = "sous-total")));
        SOMME(FILTRE($C$47:$C48 * $E$47:$E48; _idST = MAX(_idST); 0))
    )
)

Et pour la somme en BD13 sans les sous-totaux :

=SOMME.SI(Tableau7[Colonne3]; "<>sous-total"; Tableau7[Colonne5])

Pour info, c'est le groupe "LET" qui s'occupe du calcul des sous-totaux

Hello,

je tourne sur Office 360

Vous avez une version au rabais ?

Qui c'est qui vous a fauché les 5 qui manquent ?

Plus sérieux : mettez cette information dans votre profil (à la place de Français qui n'est pas une information pertinente), sinon vous devrez le spécifier à chaque fois

Merci, c'est parfait.

J'ai mis à jour la version sur mon profil, Pour info, le vendeur m'a dit que la 360, c'est la version pas cher mon frère, t'inquiète, ça marche pareil, promis.

Je dois m'inquiéter ?

Bon, j'ai voulu faire un rajout d'une colonne + case à puce pour faire une formule de SI, jusqu'à là tout va bien.

Mais si je veux faire la somme en E27 j'ai uniquement la somme autre que sous-total, il fait tout le contraire de l'autre colonne F, il faudrait qu'il fasse la même chose.

Et je sais absolument pas pourquoi ça veut pas…

Bonjour,

365 la moins chère... Oui et non, ça reste un abonnement donc sur le long terme c'est la plus chère Par contre elle est toujours à jour + pas mal de services.

Pour revenir sur votre dernière question, si j'ai bien compris vous souhaitez sommer seulement les sous-totaux, donc dans ce cas il faut retirer le symbole différent de dans la formule : <>. Ce qui donne :

=SOMME.SI(Tableau7[Colonne3]; "sous-total"; Tableau7[Colonne7])

J'ai peut-être mal compris cela dit... N'hésitez pas à indiquer le résultat attendu ou "expliquer" votre méthode de calcul étape par étape.

En fait il faudrait que ça additionne soit les postes individuels sans les sous-total soit que ça additionne uniquement les sous-total.

ah oui, évidemment.

J'avoue que je ne comprends pas trop pourquoi votre formule originale ne fonctionne pas, car pour moi elle était très bien pensée. Une alternative (qui fonctionne) est :

=SOMME(FILTRE(Tableau7[Colonne5];Tableau7[Colonne3]<>"sous-total";0))

Toujours pas, la somme est à faire que sur la colonne 7 du tableau.

Même en changeant la bonne colonne sur ta formule, ça additionne que les postes unitaires. Il faudrait que, quand un ou plusieurs sous-totaux sont sélectionnés sur les puces, seulement eux soient additionnés, et si pas de sous-total, juste les unitaires.

Bon, j'ai par trouvé une solution "sale" en trois étapes, mais je suis sûr qu'il est possible de le faire en une seule.

Pas très bien compris désolé...

Bon si vous avez résolu c'est l'essentiel, auquel cas pensez à clôturer le fil.

Bonne journée